contrib/paclog-pkglist: new contribution

converts a pacman log file to a list of installed packages, which should
match the output of `pacman -Q'.

Signed-off-by: Dave Reisner <dreisner@archlinux.org>
Signed-off-by: Dan McGee <dan@archlinux.org>

contrib/Makefile.am

@@ -13,6 +13,7 @@ EXTRA_DIST = \
 	PKGBUILD.vim \
 	bacman.in \
 	bash_completion.in \
+	paclog-pkglist \
 	pacdiff.in \
 	paclist.in \
 	pacscripts.in \

contrib/paclog-pkglist

@@ -0,0 +1,57 @@
+#!/bin/awk -f
+#
+# paclog-pkglist - Parse a log file into a list of currently installed packages
+#
+# Copyright (C) 2011 Dave Reisner <dave@archlinux.org>
+#
+# This program is free software; you can redistribute it and/or
+# modify it under the terms of the GNU General Public License
+# as published by the Free Software Foundation; either version 2
+# of the License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+BEGIN {
+  if (ARGC < 2) {
+    printf "usage:   log2pkglist <pacman log>\n"
+    printf "example: log2pkglist /var/log/pacman.log\n"
+    exit
+  }
+}
+
+{
+  action  = $3
+  pkgname = $4
+  pkgver  = $5
+  upgver  = $7
+}
+
+NF == 5 && action == "installed" {
+  gsub(/[()]/, "", pkgver)
+  pkg[pkgname] = pkgver
+  next
+}
+
+NF == 7 && action == "upgraded" {
+  sub(/\)/, "", upgver)
+  pkg[pkgname] = upgver
+  next
+}
+
+NF == 5 && action == "removed" {
+  pkg[pkgname] = -1
+}
+
+END {
+  for (i in pkg) {
+    if (pkg[i] != -1) {
+      printf "%s %s\n",i,pkg[i]
+    }
+  }
+}