pacman/contrib/zsh_completion

# file: /usr/share/zsh/site-functions/_pacman
# use the following in your zsh config:
#   compdef pacman pacman.static=pacman

typeset -A opt_args

# options for passing to _arguments: main pacman commands
_pacman_opts_commands=(
	'-A[Add a package to the system]'
	'-Q[Query the package database]'
	'-R[Remove a package from the system]'
	'-S[Synchronize packages]'
	'-U[Upgrade a package]'
	'-V[Display version and exit]'
	'-h[Display usage]'
)

# options for passing to _arguments: options common to all commands
_pacman_opts_common=(
	'-b[Alternate database location]:database_location:_files -/'
	'-h[Display syntax for the given operation]'
	'-r[Set alternate installation root]:installation root:_files -/'
	'-v[Be more verbose]'
	'--config[An alternate configuration file]:config file:_files'
	'--noconfirm[Do not ask for confirmation]'
)

# options for passing to _arguments: options for --add, and --update commands
_pacman_opts_pkgfile=(
	'-d[Skip dependency checks]'
	'-f[Overwrite conflicting files]'
	'*:package file:_files -g "*.pkg.tar.gz(.)"'
)

# options for passing to _arguments: subactions for --query command
_pacman_opts_query_actions=(
	'-e[List orphaned packages]:*:orphans:->query_orphans'
	'-g[View all members of a package group]:*:package groups:->query_group'
	'-o[Query the package that owns a file]:file:_files'
	'-p[Package file to query]:*:package file:->query_file'
	'-s[Search package names and descriptions]:*:search text:->query_search'
)

# options for passing to _arguments: options for --query and subcommands
_pacman_opts_query_modifiers=(
	'-i[View package information]'
	'-l[List package contents]'
)

# options for passing to _arguments: options for --remove command
_pacman_opts_remove=(
	'-c[Remove all dependent packages]'
	'-d[Skip dependency checks]'
	'-k[Only remove database entry, do not remove files]'
	'-n[Remove protected configuration files]'
	'-s[Remove dependencies not required by other packages]'
	'*:installed package:_pacman_completions_installed_packages'
)

# options for passing to _arguments: options for --sync command
_pacman_opts_sync_actions=(
	'*-c[Remove old packages from cache]:*:clean:->sync_clean'
	'-g[View all members of a package group]:*:package groups:->sync_group'
	'-s[Search package names and descriptions]:*:search text:->sync_search'
)

# options for passing to _arguments: options for --sync command
_pacman_opts_sync_modifiers=(
	'-d[Skip dependency checks]'
	'-f[Overwrite conflicting files]'
	'-i[View package information]'
	'-l[List all packages in a repository]'
	'-p[Print download URIs for each package to be installed]'
	'-u[Upgrade all out-of-date packages]'
	'-w[Download packages only]'
	'-y[Download fresh package databases]'
	'*--ignore[Ignore a package upgrade]:package:_pacman_completions_installed_packages'
)

# handles --action subcommand
_pacman_action_add() {
	_arguments -s : \
		"$_pacman_opts_common[@]" \
		"$_pacman_opts_pkgfile[@]"
}

# handles --help subcommand
_pacman_action_help() {
	_arguments -s : \
		"$_pacman_opts_commands[@]"
}

# handles cases where no subcommand has yet been given
_pacman_action_none() {
	_arguments -s : \
		"$_pacman_opts_commands[@]"
}

# handles --query subcommand
_pacman_action_query() {
	local context state line
	typeset -A opt_args
	
#	_arguments -s : \
#		"$_pacman_opts_common[@]" \
#		"$_pacman_opts_query_actions[@]" \
#		"$_pacman_opts_query_modifiers[@]"
		
	case $state in
		query_file)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:package file:_files -g "*.pkg.tar.gz"'
				;;
		query_group)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:groups:_pacman_completions_installed_groups'
				;;
		query_orphans)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]"
				;;
		query_owner)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:file:_files'
				;;
		query_search)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:search text: '
				;;
		*)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_actions[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:package:_pacman_completions_installed_packages'
				;;
	esac
}

# handles --remove subcommand
_pacman_action_remove() {
	_arguments -s : \
		"$_pacman_opts_common[@]" \
		"$_pacman_opts_remove[@]"
}

# handles --sync subcommand
_pacman_action_sync() {
	local context state line
	typeset -A opt_args
	
#	_arguments -s : \
#		"$_pacman_opts_common[@]" \
#		"$_pacman_opts_sync_actions[@]" #\
#		#"$_pacman_opts_sync_modifiers[@]"
		
	case $state in
		sync_clean)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_sync_modifiers[@]" \
				'*-c[Remove old packages from cache]' \
				;;
		sync_group)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_sync_modifiers[@]" \
				'*:package group:_pacman_completions_all_groups'
				;;
		sync_search)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_sync_modifiers[@]" \
				'*:search text: '
				;;
		*)
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_sync_modifiers[@]" \
				'*:package:_pacman_completions_all_packages'
				;;
		esac
}

# handles --upgrade subcommand
_pacman_action_upgrade() {
	_arguments -s : \
		"$_pacman_opts_common[@]" \
		"$_pacman_opts_pkgfile[@]"
}

# handles --version subcommand
_pacman_action_version() {
	# no further arguments
	return 0
}

# provides completions for package groups
_pacman_completions_all_groups() {
	local -a cmd groups
	_pacman_get_command
	groups=( $(_call_program groups $cmd[@] -Sg | grep -e \^$PREFIX) )
	compadd "$@" -a groups
}

# provides completions for packages available from repositories
_pacman_completions_all_packages() {
	local -a cmd packages repositories

	repositories=( $(_call_program repositories cat /etc/pacman.conf | grep "^\[" | sed "s,\(\[\|\]\),,g" | grep -v "^options" | sort -u) )
	# these can be specified as either 'package' or 'repository/package'
	if [[ "$PREFIX" == "" ]] ; then
		packages=( $(_call_program packages ls /var/lib/pacman/sync/${^repositories} | grep -v "^/" | sed "s,\-[^-]*\-[^-]*$,," | sort -u) )
	else
		packages=( $(_call_program packages ls /var/lib/pacman/sync/${^repositories} | grep -v "^/" | grep -e \^$PREFIX | sed "s,\-[^-]*\-[^-]*$,," | sort -u) )
	fi
	compadd "$@" -a packages
}

# provides completions for package groups
_pacman_completions_installed_groups() {
	local -a cmd groups
	_pacman_get_command
	groups=( $(_call_program installed_groups $cmd[@] -Qg | cut -d' ' -f1 | grep -e \^$PREFIX | sort -u) )
	compadd "$@" -a groups
}

# provides completions for installed packages
_pacman_completions_installed_packages() {
	local -a cmd packages
	packages=( $(_call_program installed_packages ls /var/lib/pacman/local | grep "^$PREFIX" | sed "s,\-[^-]*\-[^-]*$,,") )
	compadd "$@" -a packages
}

# provides completions for repository names
_pacman_completions_repositories() {
	local -a cmd repositories
	repositories=( $(_call_program repositories cat /etc/pacman.conf | grep "^\[" | sed "s,\(\[\|\]\),,g" | grep -v "^options" | grep "^$PREFIX" | sort -u) )
	compadd "$@" -a repositories
}

# builds command for invoking pacman in a _call_program command - extracts
# relevant options already specified (config file, etc)
# $cmd must be declared by calling function
_pacman_get_command() {
	# this is mostly nicked from _perforce
	cmd=( "pacman" )
	integer i
	for (( i = 2; i < CURRENT - 1; i++ )); do
		if [[ ${words[i]} = "--config" || ${words[i]} = "--root" ]]; then
			cmd+=( ${words[i,i+1]} )
		fi
	done
}

# main dispatcher
_pacman() {
	case $words[2] in
		-A*)  _pacman_action_add      ;;
		-Qg) # ipkg groups
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:groups:_pacman_completions_installed_groups'
				;;
		-Qo) # file *.pkg.tar.gz
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:package file:_files'
				;;
		-Qp) # file *.pkg.tar.gz
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_query_modifiers[@]" \
				'*:package file:_files -g "*.pkg.tar.gz"'
				;;
		-Q*)  _pacman_action_query    ;;
		-R*)  _pacman_action_remove   ;;
		-Sl) # repos
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_sync_modifiers[@]" \
				'*:package repo:_pacman_completions_repositories' \
				;;
		-Sg) # pkg groups
			_arguments -s : \
				"$_pacman_opts_common[@]" \
				"$_pacman_opts_sync_modifiers[@]" \
				'*:package group:_pacman_completions_all_groups'
				;;
		-S*)  _pacman_action_sync     ;;
		-U*)  _pacman_action_upgrade  ;;
		-V*)  _pacman_action_version  ;;
		-h*)  _pacman_action_help     ;;
		-  )  _pacman_action_none     ;;
		*  )  return 1                ;;
	esac
}

# run the main dispatcher
_pacman "$@"