buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:0.5.+'
    }
}

apply plugin: 'android'

repositories {
    mavenCentral()
}

dependencies {
    compile fileTree(dir: 'libs', includes: ['*.jar'], excludes: ['android-support-v4.jar'])
    compile 'com.android.support:support-v4:13.0.+'
    compile 'com.actionbarsherlock:actionbarsherlock:4.4.+@aar'
}

android {
    compileSdkVersion 18
    buildToolsVersion "18.0.1"

    defaultConfig {
        minSdkVersion 8
        targetSdkVersion 18
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
        }

        instrumentTest.setRoot('tests')
    }

    if (project.hasProperty('signingStoreLocation')) {
      /*
       * To sign release build, create file gradle.properties in .gradle/ with this content:
       *
       * signingStoreLocation=/home/key.store
       * signingStorePassword=xxx
       * signingKeyAlias=alias
       * signingKeyPassword=xxx
       */
      signingConfigs {
          myConfig {
              storeFile file(signingStoreLocation)
              storePassword signingStorePassword
              keyAlias signingKeyAlias
              keyPassword signingKeyPassword
          }
      }

        buildTypes {
            release {
                signingConfig signingConfigs.myConfig
            }
        }
    }
}