open-keychain/OpenKeychain/build.gradle

apply plugin: 'android'
apply plugin: 'robolectric'

dependencies {
    // NOTE: Always use fixed version codes not dynamic ones, e.g. 0.7.3 instead of 0.7.+, see README for more information

    compile 'com.android.support:support-v4:19.1.0'
    compile 'com.android.support:appcompat-v7:19.1.0'
    compile project(':extern:openpgp-api-lib')
    compile project(':extern:openkeychain-api-lib')
    compile project(':extern:html-textview')
    compile project(':extern:StickyListHeaders:library')
    compile project(':extern:AndroidBootstrap:AndroidBootstrap')
    compile project(':extern:zxing-qr-code')
    compile project(':extern:zxing-android-integration')
    compile project(':extern:spongycastle:core')
    compile project(':extern:spongycastle:pg')
    compile project(':extern:spongycastle:pkix')
    compile project(':extern:spongycastle:prov')
    compile project(':extern:AppMsg:library')
    compile project(':extern:SuperToasts:supertoasts')
    compile project(':extern:dnsjava')


    // Unit tests are run with Robolectric
    testCompile 'junit:junit:4.11'
    testCompile 'org.robolectric:robolectric:2.3'
    testCompile 'com.squareup:fest-android:1.0.8'
    testCompile 'com.google.android:android:4.1.1.4'
    testCompile 'com.android.support:support-v4:19.1.0'
    testCompile 'com.android.support:appcompat-v7:19.1.0'
    testCompile project(':extern:openpgp-api-lib')
    testCompile project(':extern:openkeychain-api-lib')
    testCompile project(':extern:html-textview')
    testCompile project(':extern:StickyListHeaders:library')
    testCompile project(':extern:AndroidBootstrap:AndroidBootstrap')
    testCompile project(':extern:zxing-qr-code')
    testCompile project(':extern:zxing-android-integration')
    testCompile project(':extern:spongycastle:core')
    testCompile project(':extern:spongycastle:pg')
    testCompile project(':extern:spongycastle:pkix')
    testCompile project(':extern:spongycastle:prov')
    testCompile project(':extern:AppMsg:library')
    testCompile project(':extern:SuperToasts:supertoasts')

}

android {
    compileSdkVersion 19
    buildToolsVersion "19.1"

    defaultConfig {
        minSdkVersion 15
        targetSdkVersion 19
    }

    /*
     * To sign release build, create file gradle.properties in ~/.gradle/ with this content:
     *
     * signingStoreLocation=/home/key.store
     * signingStorePassword=xxx
     * signingKeyAlias=alias
     * signingKeyPassword=xxx
     */
    if (project.hasProperty('signingStoreLocation') &&
            project.hasProperty('signingStorePassword') &&
            project.hasProperty('signingKeyAlias') &&
            project.hasProperty('signingKeyPassword')) {
        println "Found sign properties in gradle.properties! Signing build…"
        
        signingConfigs {
            release {
                storeFile file(signingStoreLocation)
                storePassword signingStorePassword
                keyAlias signingKeyAlias
                keyPassword signingKeyPassword
            }
        }

        buildTypes.release.signingConfig = signingConfigs.release
    } else {
        buildTypes.release.signingConfig = null
    }
    
    // NOTE: Lint is disabled because it slows down builds,
    // to enable it comment out the code at the bottom of this build.gradle
    lintOptions {
        // Do not abort build if lint finds errors
        abortOnError false

        checkAllWarnings true
        htmlReport true
        htmlOutput file("lint-report.html")
    }
}

// NOTE: This disables Lint!
tasks.whenTaskAdded { task ->
    if (task.name.equals("lint")) {
        task.enabled = false
    }
}