arch-ppa/src/dino-git/PKGBUILD

54 lines
2.0 KiB
Bash

# Maintainer: Seppia <seppia@seppio.fish>
# Contributor: svalo <me@valo.space>
pkgname=dino-git
pkgver=r721.cd3a119
pkgrel=1
pkgdesc="Simple and modern Jabber/XMPP client written in vala"
arch=('i686' 'x86_64' 'aarch64')
url="https://github.com/dino/dino"
license=('GPL3')
depends=('glib2>=2.38' 'glib-networking' 'gtk3>=3.22' 'gpgme' 'libgee>=0.10' 'libgcrypt' 'libsoup' 'sqlite' 'qrencode' 'libsignal-protocol-c' )
makedepends=('git' 'cmake' 'vala>=0.34' 'ninja')
optdepends=('libcanberra: audio notification support')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('dino::git+https://github.com/dino/dino')
sha512sums=('SKIP')
### Any or all of the following plugin can be disabled: omemo, openpgp, http-files. Populate following string as per your needs and uncomment it.
# _DISABLE_PLUGINS="--disable-plugin='omemo;openpgp;http-files'"
### Any or all of the following plugin can be enabled: notification-sound. Populate the following string as per you needs and uncomment it.
### Install any needed optional dependency before
#_ENABLE_PLUGINS="--enable-plugin='notification-sound'"
### Since 55b148a0f78c1abef57c21b2a84d97cad32b2290 dino uses by default the shared libsignal library.
# To restore the old behaviour add '--with-libsignal-in-tree' flag to configure
pkgver() {
cd "${srcdir}/${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${pkgname%-git}"
./configure $_DISABLE_PLUGINS $_ENABLE_PLUGINS --with-tests --prefix="/usr" CC="$CC" CFLAGS="$CFLAGS" VALACFLAGS="$VALACFLAGS"
sed -i '/SrvRecordsTls/d' libdino/src/service/module_manager.vala
sed -i 's/try{/try{\n GLib.Environment.set_variable("GDK_DPI_SCALE", "1.5", false);/' main/src/main.vala
make
}
package() {
cd "${srcdir}/${pkgname%-git}"
make DESTDIR="${pkgdir}/" install
}
check() {
cd "${srcdir}/${pkgname%-git}"
echo "Executing xmpp-vala-test:"
build/xmpp-vala-test
}