66 lines
2.5 KiB
Bash
66 lines
2.5 KiB
Bash
# Maintainer: Ashley Whetter <(firstname) @ awhetter.co.uk>
|
|
# Contributor: Eothred <yngve.levinsen@gmail.com>
|
|
|
|
pkgname=spotify
|
|
pkgver=1.0.94.262
|
|
_i386_pkgver=1.0.72.117
|
|
_anotherpkgver=.g3d5c231c
|
|
_i386_anotherpkgver=.g6bd7cc73
|
|
_amd64_pkgrel=9
|
|
_i386_pkgrel=35
|
|
pkgrel=1
|
|
pkgdesc="A proprietary music streaming service"
|
|
arch=('x86_64' 'i686')
|
|
license=('custom:"Copyright (c) 2006-2010 Spotify Ltd"')
|
|
url="http://www.spotify.com"
|
|
options=('!strip')
|
|
|
|
source=('spotify_x86_64'
|
|
'spotify_i686'
|
|
'spotify.protocol'
|
|
'LICENSE')
|
|
sha256sums=('2a9f88dd80a542e0e9cfeea0b823d7cec54b67b42b402c5efee09d333a1820de'
|
|
'989920e9360cadc1a8103b8c04acf0c87cb7911eb9a09dddb0cf4708d6249d34'
|
|
'af54f3b90cac46fa100b3f919a9225d10d847617d24aa9af3d832e7689f482c3'
|
|
'4e8bea31ca27e16cac9c9dcd8f6ec27e1f82b45de86d6fee7a1e77e23f884b92')
|
|
sha256sums_x86_64=('92803d614da2fd4802f801d85da9cf786f34216bbfa6085d5791c3e8350b4f44')
|
|
sha256sums_i686=('f5ac29e8374901ce7401825d13471c03bcf6ec8106f8c210c710b0a8d7b22ca9')
|
|
|
|
source_x86_64=("http://repository.spotify.com/pool/non-free/s/spotify-client/spotify-client_${pkgver}${_anotherpkgver}-${_amd64_pkgrel}_amd64.deb")
|
|
|
|
source_i686=("http://repository.spotify.com/pool/non-free/s/spotify-client/spotify-client_${_i386_pkgver}${_i386_anotherpkgver}-${_i386_pkgrel}_i386.deb")
|
|
|
|
depends=("alsa-lib>=1.0.14" "gconf" "gtk2" "glib2" "nss" "libsystemd" "libxtst" "libx11" "libxss" "openssl-1.0" "desktop-file-utils" "rtmpdump")
|
|
depends_x86_64=('libcurl-gnutls')
|
|
depends_i686=('libcurl-compat')
|
|
optdepends=('ffmpeg-compat-54: Adds support for playback of local files'
|
|
'zenity: Adds support for importing local files'
|
|
'libnotify: Desktop notifications'
|
|
)
|
|
|
|
package() {
|
|
cd "${srcdir}"
|
|
|
|
tar -xzf data.tar.gz -C "${pkgdir}"
|
|
|
|
install -D "${pkgdir}"/usr/share/spotify/spotify.desktop "${pkgdir}"/usr/share/applications/spotify.desktop
|
|
install -D "${pkgdir}"/usr/share/spotify/icons/spotify-linux-512.png "${pkgdir}"/usr/share/pixmaps/spotify-client.png
|
|
|
|
for size in 22 24 32 48 64 128 256 512; do
|
|
install -D "${pkgdir}/usr/share/spotify/icons/spotify-linux-$size.png" \
|
|
"${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/spotify.png"
|
|
done
|
|
|
|
chmod -R go-w "${pkgdir}"/usr
|
|
|
|
# Bin Script
|
|
rm "${pkgdir}"/usr/bin/spotify
|
|
install -Dm755 "${srcdir}/spotify_${CARCH}" "${pkgdir}/usr/bin/spotify"
|
|
|
|
# Copy protocol file for KDE
|
|
install -Dm644 "${srcdir}/spotify.protocol" "${pkgdir}/usr/share/kservices5/spotify.protocol"
|
|
|
|
# License
|
|
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
|
}
|