diff --git a/src/amavisd-new/PKGBUILD b/src/amavisd-new/PKGBUILD
new file mode 100644
index 0000000..b18913e
--- /dev/null
+++ b/src/amavisd-new/PKGBUILD
@@ -0,0 +1,78 @@
+# Maintainer: Yardena Cohen <yardenack at gmail dot com>
+
+pkgname=amavisd-new
+pkgver=2.11.0
+pkgrel=1
+pkgdesc="High-performance interface between mailer (MTA) and content checkers"
+arch=('any')
+url="http://www.ijs.si/software/amavisd/"
+license=('GPL')
+depends=(
+    'perl>=5.8.2'
+    'perl-archive-zip>=1.14'
+    'perl-convert-tnef'
+    'perl-convert-uulib>=1.4-5'
+    'perl-mime-tools'
+    'perl-mailtools>=1.58'
+    'perl-net-libidn'
+    'perl-net-server>=0.88'
+    'perl-io-socket-inet6'
+    'perl-io-stringy'
+    'perl-unix-syslog>=1.1-4'
+    'perl-mail-dkim>=0.31'
+    'perl-berkeleydb>=0.42'
+	 'bzip2'
+	 'gzip'
+)
+optdepends=(
+    'perl-file-libmagic'
+	 'arc:        Decoder for: .arc'
+	 'arj:        Decoder for: .arj .exe'
+    'lrzip:      Decoder for: .lrz'
+    'lz4:        Decoder for: .lz4'
+    'lzo:        Decoder for: .lzo'
+	 'p7zip:      Decoder for: .7z'
+	 'unrar:      Decoder for: .rar'
+	 'rpmextract: Decoder for: .rpm'
+)
+backup=('etc/amavisd/amavisd.conf' 'etc/amavisd/amavisd-custom.conf')
+source=("http://www.ijs.si/software/amavisd/amavisd-new-${pkgver}.tar.xz"
+        "service"
+        "tmpfiles")
+sha256sums=('b41de4f0796cb344120c9792c82fc25177cbf9f51aaa5f91536cdf34aea89906'
+            'cdfc26a15049ea8526b552ab1bef9ccf9bc8608ee65897801d9ea87de84a7435'
+            '84bccf5f2b2740b25ea7d15237607f894b7ce7558e1ecba67f2d005497b8bf25')
+install=install
+
+prepare() {
+    sed -i \
+        -e "s/# @bypass_virus_checks_maps = (1)/@bypass_virus_checks_maps = (1)/g" \
+        -e "s/# @bypass_spam_checks_maps  = (1)/@bypass_spam_checks_maps = (1)/g" \
+        -e "s/\\\$daemon_user  = 'vscan'/\\\$daemon_user  = 'amavis'/g" \
+        -e "s/\\\$daemon_group = 'vscan'/\\\$daemon_group = 'amavis'/g" \
+        -e "sX# \\\$MYHOME = '/var/amavis'X\\\$MYHOME = '/var/spool/amavis'Xg" \
+        -e "sX\\\$QUARANTINEDIR = '/var/virusmails'X\\\$QUARANTINEDIR = \"\\\$MYHOME/virus\"Xg" \
+        -e "sX# \\\$pid_file  = \"\\\$MYHOME/var/amavisd.pid\"X\\\$pid_file = \"/run/amavis/pid\"Xg" \
+        -e "sX# \\\$lock_file = \"\\\$MYHOME/var/amavisd.lock\"X\\\$lock_file = \"/run/amavis/lock\"Xg" \
+        -e "sX\\\$unix_socketname = \"\\\$MYHOME/amavisd.sock\"X\\\$unix_socketname = \"/run/amavis/sock\"Xg" \
+        ${srcdir}/amavisd-new-${pkgver}/amavisd.conf
+}
+
+package() {
+    cd ${srcdir}/amavisd-new-${pkgver}
+    install -D -m644 ${srcdir}/service         ${pkgdir}/usr/lib/systemd/system/amavisd.service
+    install -D -m644 ${srcdir}/tmpfiles        ${pkgdir}/usr/lib/tmpfiles.d/amavisd.conf
+    install -D -m755 JpegTester.pm             ${pkgdir}/usr/share/perl5/vendor_perl/JpegTester.pm
+    install -D -m644 LDAP.ldif                 ${pkgdir}/etc/openldap/schema/amavisd-new.ldif
+    install -D -m644 LDAP.schema               ${pkgdir}/etc/openldap/schema/amavisd-new.schema
+	 install -D -m750 -o 333 -g 333 -d          ${pkgdir}/var/spool/amavis/{,db,tmp,var,virus}
+
+	 mkdir -p \
+		  ${pkgdir}/etc/amavisd \
+		  ${pkgdir}/usr/share/doc/amavis \
+		  ${pkgdir}/usr/bin
+
+    install -D -m644 -t ${pkgdir}/etc/amavisd             amavisd{.conf,-custom.conf,.conf-default}
+    install -D -m644 -t ${pkgdir}/usr/share/doc/amavis    amavisd-new-{qmqpqq,courier}.patch
+    install -D -m755 -t ${pkgdir}/usr/bin p0f-analyzer.pl amavisd{,-{agent,nanny,release,signer,snmp-subagent{,-zmq}}}
+}
diff --git a/src/brother-hl2170w/PKGBUILD b/src/brother-hl2170w/PKGBUILD
new file mode 100644
index 0000000..161c02e
--- /dev/null
+++ b/src/brother-hl2170w/PKGBUILD
@@ -0,0 +1,63 @@
+# Maintainer: Mark Mykkanen <quickcougar at gmail dot com>
+# Contributor: Mark Mykkanen <quickcougar at gmail dot com>
+pkgname="brother-hl2170w"
+pkgver="2.0.2_1"
+pkgrel=1
+pkgdesc="LPR and CUPS driver for the Brother HL2170W"
+arch=('i686' 'x86_64')
+url="http://solutions.brother.com/linux/en_us/"
+license=('custom:brother commercial license')
+depends=('cups')
+install='brother-hl2170w.install'
+source=(
+	"http://www.brother.com/pub/bsc/linux/dlf/brhl2170wlpr-${pkgver//_/-}.i386.rpm"
+	"http://www.brother.com/pub/bsc/linux/dlf/cupswrapperHL2170W-${pkgver//_/-}.i386.rpm"
+	'cupswrapper-license.txt'
+	'lpr-license.txt'
+)
+md5sums=('2d7fe5114239b48dad38e08e24c9fca0'
+         '5d2b95b7c148eabf21866604e6e5cf3a'
+         '97ad0cffd216059e9d1d3121899d8646'
+         '5e87a3dc0f3e3438c088eda0f3565f0d')
+if test "$CARCH" == x86_64; then
+  depends+=('lib32-glibc')
+fi
+prepare() {
+#  do not install in '/usr/local'
+	if [ -d $srcdir/usr/local/Brother ]; then
+		install -d $srcdir/usr/share
+		mv $srcdir/usr/local/Brother/ $srcdir/usr/share/brother
+		rm -rf $srcdir/usr/local
+    sed -i 's|/usr/local/Brother|/usr/share/brother|g' `grep -lr '/usr/local/Brother' ./`
+  fi
+# setup cups-directories
+	install -d $srcdir/usr/share/cups/model
+	install -d $srcdir/usr/lib/cups/filter
+# go to the cupswrapper directory and find the source file from wich to generate a ppd and
+# wrapper-file
+	cd `find . -type d -name 'cupswrapper'`
+	if [ -f cupswrapper* ]; then
+		_wrapper_source=`ls cupswrapper*`
+		sed -i '/^\/etc\/init.d\/cups/d' $_wrapper_source
+		sed -i '/^sleep/d' $_wrapper_source
+		sed -i '/^lpadmin/d' $_wrapper_source
+		sed -i 's|/usr|$srcdir/usr|g' $_wrapper_source
+		sed -i 's|/opt|$srcdir/opt|g' $_wrapper_source
+		sed -i 's|/model/Brother|/model|g' $_wrapper_source
+		sed -i 's|lpinfo|echo|g' $_wrapper_source
+		export srcdir=$srcdir
+		./$_wrapper_source
+		sed -i 's|$srcdir||' $srcdir/usr/lib/cups/filter/*lpdwrapper*
+		sed -i "s|$srcdir||" $srcdir/usr/lib/cups/filter/*lpdwrapper*
+		rm $_wrapper_source
+	fi
+#  /etc/printcap is managed by cups
+	rm `find $srcdir -type f -name 'setupPrintcap*'`
+}
+package() {
+	cp -R $srcdir/usr $pkgdir
+	if [ -d $srcdir/opt ]; then cp -R $srcdir/opt $pkgdir; fi
+	install -m 644 -D cupswrapper-license.txt \
+    $pkgdir/usr/share/licenses/${pkgname}/cupswrapper-licence.txt
+	install -m 644 -D lpr-license.txt $pkgdir/usr/share/licenses/${pkgname}/lpr-licence.txt
+}
diff --git a/src/cndrvcups-common-lb/PKGBUILD b/src/cndrvcups-common-lb/PKGBUILD
new file mode 100644
index 0000000..870e72c
--- /dev/null
+++ b/src/cndrvcups-common-lb/PKGBUILD
@@ -0,0 +1,119 @@
+# Maintainer : Lone_Wolf lonewolf@xs4all.nl
+# Contributor: Steven She <mintcoffee@gmail.com>
+# Contributor: vbPadre <vbpadre@gmail.com>
+
+pkgbase=cndrvcups-common-lb
+pkgname=cndrvcups-common-lb
+# used this name to avoid conflict with the existing cndrvcups-common (no longer in aur) which was wrong version for cndrvcups-lb
+_pkgname=cndrvcups-common
+pkgver=3.60
+pkgrel=1
+pkgdesc="Common printer driver modules for cndrvcups-lb package, built from source"
+arch=('i686' 'x86_64')
+url="http://support-au.canon.com.au/contents/AU/EN/0100270808.html"
+license=('GPL' 'MIT' 'custom')
+depends_i686=('libglade' 'gcc-libs')
+depends_x86_64=('libglade' 'lib32-gcc-libs')
+makedepends=('automake' 'autoconf')
+conflicts=('cndrvcups-lb-bin')
+# http://pdisp01.c-wss.com/gdl/WWUFORedirectTarget.do?id=MDEwMDAwMjcwODE0&cmp=ABS&lang=EN
+source=(Linux_UFRII_PrinterDriver_V320_uk_EN.tar.gz::'http://pdisp01.c-wss.com/gdl/WWUFORedirectTarget.do?id=MDEwMDAwMjcwODE0&cmp=ABS&lang=EN')
+options=('!emptydirs' '!strip' 'staticlibs')
+sha512sums=('fc35670a07f067b6ccdebf5b96590eafac2ed984faaa8a90ce44dd44396d6de0964f6352cae0fdf8ce1f6127ebf3ea9f6610b56ba7dd9a7f382bd1c6d588a801')
+
+# build instructions are adapted from upstream cndrvcups-common.spec file
+
+prepare() {
+    cd "${srcdir}"/Linux_UFRII_PrinterDriver_V320_uk_EN/Sources
+    bsdtar xf "${_pkgname}"-"${pkgver}"-1.tar.gz -C "${srcdir}"
+}
+
+build() {
+
+    cd "${srcdir}"/"${_pkgname}"-"${pkgver}"/buftool
+    autoreconf -i
+    ./autogen.sh --prefix=/usr/ --enable-progpath=/usr/bin --libdir=/usr/lib
+
+    cd "${srcdir}"/"${_pkgname}"-"${pkgver}"/cngplp
+    _cflags="${CFLAGS}"
+    CFLAGS="${CFLAGS} $(pkg-config --cflags --libs gmodule-2.0)"
+    autoreconf -i
+    ./autogen.sh --prefix=/usr --libdir=/usr/lib 
+    CFLAGS="${_cflags}"
+
+    cd "${srcdir}"/"${_pkgname}"-"${pkgver}"/backend
+    autoreconf -i
+    ./autogen.sh --prefix=/usr --libdir=/usr/lib
+
+    cd "${srcdir}"/"${_pkgname}"-"${pkgver}"
+    make
+
+    cd "${srcdir}"/"${_pkgname}"-"${pkgver}"/c3plmod_ipc
+    make 
+}
+package()
+{
+
+    cd "${srcdir}"/"${_pkgname}"-"${pkgver}"
+    mkdir -p "${pkgdir}"/usr/{bin,lib/cups/backend,include}
+    
+    if [[ ${CARCH} == "i686" ]]; then
+      _lib32dir="lib"
+    else
+      _lib32dir="lib32"
+      mkdir -p "${pkgdir}"/usr/"${_lib32dir}"
+    fi
+
+    mkdir -p "${pkgdir}"/usr/share/{caepcm,cngplp,locale/ja/LC_MESSAGES}
+
+    make install DESTDIR="${pkgdir}"
+
+    cd c3plmod_ipc
+    make install DESTDIR="${pkgdir}" LIBDIR=/usr/lib
+    cd ..
+
+    install -m 755 libs/libcaiowrap.so.1.0.0   "${pkgdir}"/usr/"${_lib32dir}"
+    install -m 755 libs/libcaiousb.so.1.0.0    "${pkgdir}"/usr/"${_lib32dir}"
+
+    install -m 755 libs/libc3pl.so.0.0.1     "${pkgdir}"/usr/"${_lib32dir}"
+    install -m 755 libs/libcaepcm.so.1.0     "${pkgdir}"/usr/"${_lib32dir}"
+
+    install -m 755 libs/libColorGear.so.0.0.0    "${pkgdir}"/usr/"${_lib32dir}"
+    install -m 755 libs/libColorGearC.so.0.0.0    "${pkgdir}"/usr/"${_lib32dir}"
+
+
+    install -m 644 data/*.ICC  "${pkgdir}"/usr/share/caepcm
+    install -m 644 data/*.PRF  "${pkgdir}"/usr/share/caepcm
+
+    install -s -m 755 libs/c3pldrv     "${pkgdir}"/usr/bin
+
+    install -m 755 libs/libcanon_slim.so.1.0.0   "${pkgdir}"/usr/"${_lib32dir}"
+
+    cd "${pkgdir}"/usr/"${_lib32dir}"
+    ln -sf libc3pl.so.0.0.1     libc3pl.so.0
+    ln -sf libc3pl.so.0.0.1     libc3pl.so
+    ln -sf libcaepcm.so.1.0     libcaepcm.so.1
+    ln -sf libcaepcm.so.1.0     libcaepcm.so
+    ln -sf libcaiowrap.so.1.0.0   libcaiowrap.so.1
+    ln -sf libcaiowrap.so.1.0.0   libcaiowrap.so
+    ln -sf libcaiousb.so.1.0.0    libcaiousb.so.1
+    ln -sf libcaiousb.so.1.0.0    libcaiousb.so
+    ln -sf libcanon_slim.so.1.0.0   libcanon_slim.so.1
+    ln -sf libcanon_slim.so.1.0.0   libcanon_slim.so
+
+    ln -sf libColorGear.so.0.0.0    libColorGear.so.0
+    ln -sf libColorGear.so.0.0.0    libColorGear.so
+    ln -sf libColorGearC.so.0.0.0   libColorGearC.so.0
+    ln -sf libColorGearC.so.0.0.0   libColorGearC.so
+
+    cd "${pkgdir}"/usr/lib
+    ln -sf libcanonc3pl.so.1.0.0    libcanonc3pl.so
+    ln -sf libcanonc3pl.so.1.0.0    libcanonc3pl.so.1
+    
+    # according to gentoo ebuild (for 2.90 )c3pldrv dlopens the absolute path /usr/lib/libc3pl.so
+    ln -s /usr/lib32/libc3pl.so libc3pl.so
+    
+    cd "${srcdir}"/"${_pkgname}"-"${pkgver}"
+    install -m755 -d "${pkgdir}"/usr/share/licenses/"${pkgname}"
+    install -m755 LICENSE-* "${pkgdir}"/usr/share/licenses/"${pkgname}"
+}
diff --git a/src/cndrvcups-lb-bin/PKGBUILD b/src/cndrvcups-lb-bin/PKGBUILD
new file mode 100644
index 0000000..b75c96d
--- /dev/null
+++ b/src/cndrvcups-lb-bin/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: Allen Choong <allencch at hotmail dot com>
+
+pkgname=cndrvcups-lb-bin
+pkgver=3.20
+pkgrel=1
+pkgdesc="Canon UFR II/UFR II LT Printer Driver (including Canon imageCLASS MF4720w)"
+url="http://support-asia.canon-asia.com/contents/ASIA/EN/0100270810.html"
+arch=('i686' 'x86_64')
+depends_i686=('libxml2' 'libcups')
+depends_x86_64=('lib32-libxml2' 'lib32-libcups')
+replaces=('canon-ufr')
+conflicts=('cndrvcups-lb')
+license=('custom')
+source=("http://gdlp01.c-wss.com/gds/8/0100002708/14/Linux_UFRII_PrinterDriver_V${pkgver/./}_uk_EN.tar.gz")
+sha256sums=('b28bc2b460aeddcb7800983d2fad8c29ea6efcc95ad767a78fe6c25d0956f242')
+
+package() {
+	if [ "${CARCH}" = 'x86_64' ]; then
+	  dir=64-bit_Driver
+	  suffix=amd64
+	elif [ "${CARCH}" = 'i686' ]; then
+	  dir=32-bit_Driver
+	  suffix=i386
+	fi
+	cd "${srcdir}/Linux_UFRII_PrinterDriver_V${pkgver/./}_uk_EN/${dir}/Debian/"
+	ar xv cndrvcups-common_3.60-1_${suffix}.deb
+	tar xzf data.tar.gz
+	ar xv cndrvcups-ufr2-uk_${pkgver}-1_${suffix}.deb
+	tar xzf data.tar.gz
+	mv usr etc ${pkgdir}
+}
diff --git a/src/cndrvcups-lb/PKGBUILD b/src/cndrvcups-lb/PKGBUILD
new file mode 100644
index 0000000..c5535ef
--- /dev/null
+++ b/src/cndrvcups-lb/PKGBUILD
@@ -0,0 +1,113 @@
+#Maintainer: Lone_Wolf <lonewolf@xs4all.nl>
+# Contributor: Steven She <mintcoffee@gmail.com>
+# Contributor: vbPadre <vbPadre@gmail.com>
+pkgbase=cndrvcups-lb
+pkgname=cndrvcups-lb
+pkgver=3.20
+pkgrel=1
+pkgdesc="Canon UFR II /LIPSLX Printer Driver build from source for LBP, iR & MF printers"
+arch=('i686' 'x86_64')
+url="http://support-au.canon.com.au/contents/AU/EN/0100270808.html"
+license=('custom')
+install=${pkgname}.install
+depends_i686=('cndrvcups-common-lb=3.60' 'libxml2')
+depends_x86_64=('cndrvcups-common-lb=3.60' 'lib32-libxml2')
+makedepends=('autoconf' 'automake')
+conflicts=('cndrvcups-lb-bin' 'cndrvcups-lb-cpca')
+source=(Linux_UFRII_PrinterDriver_V320_uk_EN.tar.gz::'http://pdisp01.c-wss.com/gdl/WWUFORedirectTarget.do?id=MDEwMDAwMjcwODE0&cmp=ABS&lang=EN'
+       'how-to.txt')
+options=('!emptydirs' '!strip' '!libtool')
+sha512sums=('fc35670a07f067b6ccdebf5b96590eafac2ed984faaa8a90ce44dd44396d6de0964f6352cae0fdf8ce1f6127ebf3ea9f6610b56ba7dd9a7f382bd1c6d588a801'
+            '736e1785c443c4d129c8801a127410012889f46691259e8a7f6a54106a0647beb5b6267aabb78b3ed0a1c7a9d8ce216e159515d3aad425812e5be52c8b58e4ee')
+         
+# build instructions are adapted from upstream cndrvcups-lb.spec file
+prepare() {
+    cd "${srcdir}"/Linux_UFRII_PrinterDriver_V320_uk_EN/Sources
+    bsdtar xf "${pkgbase}"-"${pkgver}"-1.tar.gz -C "${srcdir}"
+}
+
+build() {
+    
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"/ppd
+    autoreconf -fi
+    ./autogen.sh --prefix=/usr
+        
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"/pstoufr2cpca
+    autoreconf -fi
+    ./autogen.sh --prefix=/usr --libdir=/usr/lib
+
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"/cpca
+    autoreconf -fi
+    ./autogen.sh --prefix=/usr --enable-progpath=/usr/bin --libdir=/usr/lib
+
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"/cngplp
+    aclocal
+    autoreconf -fi
+    ./autogen.sh --prefix=/usr --libdir=/usr/lib
+    
+    cd files
+    autoreconf -fi
+    ./autogen.sh --prefix=/usr
+
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"
+    make
+    
+}
+
+package() {
+  
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"
+
+    if [[ $CARCH == "i686" ]]; then
+      _lib32dir="lib"
+    else
+      _lib32dir="lib32"
+      mkdir -p "${pkgdir}"/usr/"${_lib32dir}"
+    fi
+
+    mkdir -p "${pkgdir}"/usr/{bin,share/{caepcm,cnpkbidi,ufr2filter}}
+    make install DESTDIR="${pkgdir}"
+    
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"
+    install -m 4755 libs/cnpkmoduleufr2  "${pkgdir}"/usr/bin
+
+    install -m 755 libs/libcanonufr2.la  "${pkgdir}"/usr/"${_lib32dir}"
+    install -s -m 755 libs/libcanonufr2.so.1.0.0  "${pkgdir}"/usr/"${_lib32dir}"
+    install -s -m 755 libs/libufr2filter.so.1.0.0   "${pkgdir}"/usr/"${_lib32dir}"
+    install -s -m 755 libs/libEnoJBIG.so.1.0.0   "${pkgdir}"/usr/"${_lib32dir}"
+    install -s -m 755 libs/libEnoJPEG.so.1.0.0   "${pkgdir}"/usr/"${_lib32dir}"
+    install -s -m 755 libs/cnpkbidi   "${pkgdir}"/usr/bin
+    install -s -m 755 libs/libcaiocnpkbidi.so.1.0.0   "${pkgdir}"/usr/"${_lib32dir}"
+
+    install -m 644 data/CnLB*  "${pkgdir}"/usr/share/caepcm
+    install -m 644 libs/cnpkbidi_info* "${pkgdir}"/usr/share/cnpkbidi
+    install -m 644 libs/ThLB*  "${pkgdir}"/usr/share/ufr2filter
+
+    install -m 755 libs/libcnlbcm.so.1.0     "${pkgdir}"/usr/"${_lib32dir}"
+
+    cd "${pkgdir}"/usr/"${_lib32dir}"
+    ln -sf libcanonufr2.so.1.0.0 libcanonufr2.so
+    ln -sf libcanonufr2.so.1.0.0 libcanonufr2.so.1
+    ln -sf libufr2filter.so.1.0.0 libufr2filter.so
+    ln -sf libufr2filter.so.1.0.0 libufr2filter.so.1
+    ln -sf libEnoJBIG.so.1.0.0 libEnoJBIG.so
+    ln -sf libEnoJBIG.so.1.0.0 libEnoJBIG.so.1
+    ln -sf libEnoJPEG.so.1.0.0 libEnoJPEG.so
+    ln -sf libEnoJPEG.so.1.0.0 libEnoJPEG.so.1
+    ln -sf libcaiocnpkbidi.so.1.0.0 libcaiocnpkbidi.so
+    ln -sf libcaiocnpkbidi.so.1.0.0 libcaiocnpkbidi.so.1
+    ln -sf libcnlbcm.so.1.0     libcnlbcm.so.1
+    ln -sf libcnlbcm.so.1.0     libcnlbcm.so
+    
+    # according to Gentoo ebuild v2.90 c3pldrv dlopens the absolute path /usr/lib/libcnlbcm.so 
+    cd "${pkgdir}"/usr/lib
+    ln -s /usr/lib32/libcnlbcm.so libcnlbcm.so
+
+    cd "${srcdir}"/"${pkgbase}"-"${pkgver}"
+    install -m755 -d "${pkgdir}"/usr/share/licenses/"${pkgname}"
+    install -m644 L*-ufr2-* "${pkgdir}"/usr/share/licenses/"${pkgname}/"
+    install -m644 LICENSE-*.txt "${pkgdir}"/usr/share/licenses/"${pkgname}/"
+    install -m755 -d "${pkgdir}"/usr/share/doc/"${pkgname}"
+    install -m644 README* "${pkgdir}"/usr/share/doc/"${pkgname}"
+    install -m644 "${srcdir}"/Linux_UFRII_PrinterDriver_V320_uk_EN/Documents/guide-ufr2-3.2xUK.tar.gz "${pkgdir}"/usr/share/doc/"${pkgname}"
+}
diff --git a/src/cower/PKGBUILD b/src/cower/PKGBUILD
new file mode 100644
index 0000000..7a020b9
--- /dev/null
+++ b/src/cower/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: Dave Reisner <d@falconindy.com>
+
+pkgname=cower
+pkgver=16
+pkgrel=1
+pkgdesc="A simple AUR agent with a pretentious name"
+arch=('i686' 'x86_64')
+url="http://github.com/falconindy/cower"
+license=('MIT')
+depends=('curl' 'openssl' 'pacman' 'yajl')
+makedepends=('perl')
+source=("https://pkgbuild.com/~dreisner/sources/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig})
+validpgpkeys=('487EACC08557AD082088DABA1EB2638FF56C0C53')  # Dave Reisner
+md5sums=('f141e441b7775df3d3a1ba3a80bc3d1d'
+         'SKIP')
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  make
+  sed '/^$/q' cower.c >LICENSE
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  make PREFIX=/usr DESTDIR="$pkgdir" install
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim: ft=sh syn=sh
diff --git a/src/freeminer/PKGBUILD b/src/freeminer/PKGBUILD
new file mode 100644
index 0000000..db466c9
--- /dev/null
+++ b/src/freeminer/PKGBUILD
@@ -0,0 +1,61 @@
+# Maintainer: Alfredo Ramos <alfredo dot ramos at yandex dot com>
+# Contributor: kusakata <shohei atmark kusakata period com>
+
+pkgname=freeminer
+pkgver=0.4.14.8
+pkgrel=2
+pkgdesc='An open source sandbox game inspired by Minecraft.'
+arch=('i686' 'x86_64')
+url='http://freeminer.org/'
+license=('GPL3' 'CCPL:cc-by-sa-3.0')
+
+depends=(
+	'leveldb' 'curl' 'hiredis' 'sqlite' 'luajit' 'irrlicht'
+	'openal' 'enet' 'jsoncpp' 'libvorbis' 'hicolor-icon-theme' 'freetype2'
+)
+makedepends=('cmake' 'msgpack-c' 'clang')
+provides=("${pkgname}=${pkgver}")
+conflicts=("${pkgname}-git")
+
+source=(
+	"https://github.com/${pkgname}/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.zip"
+	'enet_shared_lib.patch'
+	'fix_msgpack.patch'
+)
+sha512sums=(
+	'093c1640c9a070fdbd45074d0a4acc5b7894d23cd436dc3cf794cee8fff92930cf26f8d802b984cb9ce19bac7fccc6e0ce948c816c9e19b9e9551e373e560beb'
+	'ac51ee33df27f9fb3bdf16c50b2a9da602d6c55bba7afe21492d0056cdfefa5f84ccfb306c23bd2bcf22066ca3ef2a952110ba0de350602393754f0466383004'
+	'4ac827ed4b1185264c6b7df279c40548b7e5dc5957129ee6dc4fe6ff05222844dabab67cf1f8c1932cac0cc691ac040812eca662d7ff36424eb3d3827bb126a0'
+)
+
+prepare() {
+	cd "${srcdir}"/${pkgname}-${pkgver}
+
+	# Use Arch's enet lib
+	patch -Np1 < ../enet_shared_lib.patch
+
+	# Fix msgpack-c v2.0.0
+	patch -Np1 < ../fix_msgpack.patch
+
+	# Create build directory
+	mkdir -p "${srcdir}"/build
+}
+
+build() {
+	# Building package
+	cd "${srcdir}"/build
+	cmake ../${pkgname}-${pkgver} \
+		-DCMAKE_C_COMPILER=clang \
+		-DCMAKE_CXX_COMPILER=clang++ \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DRUN_IN_PLACE=0 \
+		-DENABLE_SYSTEM_JSONCPP=1 \
+		-DENABLE_SYSTEM_MSGPACK=1
+	make
+}
+
+package() {
+	# Installing package
+	cd "${srcdir}"/build
+	make DESTDIR="${pkgdir}" install
+}
diff --git a/src/intellij-idea-ultimate-edition/PKGBUILD b/src/intellij-idea-ultimate-edition/PKGBUILD
new file mode 100644
index 0000000..4f12f56
--- /dev/null
+++ b/src/intellij-idea-ultimate-edition/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Urs Wolfer <uwolfer @ fwo.ch>
+
+pkgname=intellij-idea-ultimate-edition
+pkgver=2016.2.5
+_buildver=162.2228.15
+pkgrel=1
+pkgdesc="An intelligent IDE for Java, Groovy and other programming languages with advanced refactoring features intensely focused on developer productivity."
+arch=('any')
+url="https://www.jetbrains.com/idea/"
+backup=("usr/share/${pkgname}/bin/idea.vmoptions" "usr/share/${pkgname}/bin/idea64.vmoptions" "usr/share/${pkgname}/bin/idea.properties")
+license=('Commercial')
+depends=('java-environment' 'giflib' 'libxtst')
+options=(!strip)
+source=(https://download.jetbrains.com/idea/ideaIU-$pkgver-no-jdk.tar.gz \
+        intellijidea.sh \
+        jetbrains-idea.desktop
+)
+sha256sums=('51d6b74c4bc73cb9c8a24020af9488614b3f6e24a14dbb8e012fe363280e4fa7'
+            'ed7883b33b6fa9f2e303e5549bd238ceb552ec11ca116730271a58aca685229a'
+            '83af2ba8f9f14275a6684e79d6d4bd9b48cd852c047dacfc81324588fa2ff92b'
+)
+package() {
+  cd "$srcdir"
+
+  install -d -m755 "$pkgdir"/usr/{bin,share}
+  cp -a "idea-IU-$_buildver" "$pkgdir"/usr/share/"$pkgname"
+
+  # make sure that all files are owned by root
+  chown -R root:root "$pkgdir"/usr/share
+
+  find "$pkgdir"/usr/share/"$pkgname" -type d -exec chmod 0755 {} ';'
+  find "$pkgdir"/usr/share/"$pkgname" -type f -exec chmod 0644 {} ';'
+
+  chmod +x "$pkgdir"/usr/share/"$pkgname"/bin/idea.sh
+  chmod +x "$pkgdir"/usr/share/"$pkgname"/bin/fsnotifier
+  chmod +x "$pkgdir"/usr/share/"$pkgname"/bin/fsnotifier64
+
+  install -D -m755 "$srcdir"/intellijidea.sh "$pkgdir"/usr/bin/"$pkgname"
+  install -D -m644 "$srcdir"/jetbrains-idea.desktop "$pkgdir"/usr/share/applications/jetbrains-idea.desktop
+  install -D -m644 "$srcdir"/idea-IU-$_buildver/bin/idea.png "$pkgdir"/usr/share/pixmaps/"$pkgname".png
+
+  # workaround FS#40934
+  sed -i 's|lcd|on|'  "$pkgdir"/usr/share/"$pkgname"/bin/*.vmoptions
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/src/iucode-tool/PKGBUILD b/src/iucode-tool/PKGBUILD
new file mode 100644
index 0000000..ba32e44
--- /dev/null
+++ b/src/iucode-tool/PKGBUILD
@@ -0,0 +1,26 @@
+# Maintainer: Andreas Bosch <admin@progandy.de>
+pkgname=iucode-tool
+pkgver=2.0
+pkgrel=1
+pkgdesc="Tool to manipulate Intel® IA-32/X86-64 microcode bundles"
+arch=(x86_64 i686)
+url="https://gitlab.com/iucode-tool/iucode-tool/wikis/home"
+license=('GPL')
+makedepends=()
+source=("https://gitlab.com/iucode-tool/releases/raw/master/${pkgname}_${pkgver}.tar.xz"
+    "https://gitlab.com/iucode-tool/releases/raw/master/${pkgname}_${pkgver}.tar.xz.asc")
+noextract=()
+sha256sums=('55b506e8472507556ceea29cc30d5a0fbf86a626159fe45066bc31511a3f4868'
+            'SKIP')
+validpgpkeys=('C467A717507BBAFED3C160920BD9E81139CB4807') # Henrique de Moraes Holschuh <hmh@hmh.eng.br>
+
+build() {
+	cd "$srcdir/${pkgname/-/_}-$pkgver"
+	./configure --prefix=/usr --sbindir=/usr/bin
+	make
+}
+
+package() {
+	cd "$srcdir/${pkgname/-/_}-$pkgver"
+	make DESTDIR="$pkgdir/" install
+}
diff --git a/src/jdk/PKGBUILD b/src/jdk/PKGBUILD
new file mode 100644
index 0000000..30b8109
--- /dev/null
+++ b/src/jdk/PKGBUILD
@@ -0,0 +1,167 @@
+# Maintainer: Det <nimetonmaili g-mail>
+# Based on jre: https://aur.archlinux.org/packages/jre/
+
+pkgname=jdk
+_major=8
+_minor=112
+_build=b15
+pkgver=${_major}u${_minor}
+pkgrel=1
+pkgdesc="Oracle Java Development Kit"
+arch=('i686' 'x86_64')
+url=http://www.oracle.com/technetwork/java/javase/downloads/index.html
+license=('custom')
+depends=('ca-certificates-java' 'desktop-file-utils' 'hicolor-icon-theme' 'java-environment-common'
+         'java-runtime-common' 'libx11' 'libxrender' 'libxslt' 'libxtst' 'shared-mime-info' 'xdg-utils')
+optdepends=('alsa-lib: for basic sound support'
+            'eclipse: to use "Oracle Java Mission Control" plugins in Eclipse'
+            'gtk2: for Gtk+ look and feel (desktop)'
+            'ttf-font: fonts')
+provides=("java-runtime=$_major" "java-runtime-headless=$_major" "java-web-start=$_major" "java-environment=$_major"
+          "java-runtime-jre=$_major" "java-runtime-headless-jre=$_major" "java-web-start-jre=$_major" "java-environment-jdk=$_major"
+          "java-openjfx=$_major")
+
+# Variables
+DLAGENTS=('http::/usr/bin/curl -fLC - --retry 3 --retry-delay 3 -b oraclelicense=a -o %o %u')
+_jname=${pkgname}${_major}
+_jvmdir=/usr/lib/jvm/java-$_major-$pkgname
+
+backup=("etc/java-$_jname/amd64/jvm.cfg"
+        "etc/java-$_jname/images/cursors/cursors.properties"
+        "etc/java-$_jname/management/jmxremote.access"
+        "etc/java-$_jname/management/management.properties"
+        "etc/java-$_jname/security/java.policy"
+        "etc/java-$_jname/security/java.security"
+        "etc/java-$_jname/security/javaws.policy"
+        "etc/java-$_jname/content-types.properties"
+        "etc/java-$_jname/flavormap.properties"
+        "etc/java-$_jname/fontconfig.properties.src"
+        "etc/java-$_jname/logging.properties"
+        "etc/java-$_jname/net.properties"
+        "etc/java-$_jname/psfont.properties.ja"
+        "etc/java-$_jname/psfontj2d.properties"
+        "etc/java-$_jname/sound.properties")
+[[ $CARCH = i686 ]] && backup[0]="etc/java-$_jname/i386/jvm.cfg"
+options=('!strip') # JDK debug-symbols
+install=$pkgname.install
+source=("http://download.oracle.com/otn-pub/java/jce/$_major/jce_policy-$_major.zip"
+        "jconsole-$_jname.desktop"
+        "jmc-$_jname.desktop"
+        "jvisualvm-$_jname.desktop"
+        "policytool-$_jname.desktop")
+source_i686=("http://download.oracle.com/otn-pub/java/jdk/$pkgver-$_build/$pkgname-$pkgver-linux-i586.tar.gz")
+source_x86_64=("http://download.oracle.com/otn-pub/java/jdk/$pkgver-$_build/$pkgname-$pkgver-linux-x64.tar.gz")
+md5sums=('b3c7031bc65c28c2340302065e7d00d3'
+         'b4f0da18e03f7a9623cb073b65dde6c1'
+         '8f0ebcead2aecad67fbd12ef8ced1503'
+         'a4a21b064ff9f3c3f3fdb95edf5ac6f3'
+         '98245ddb13914a74f0cc5a028fffddca')
+md5sums_i686=('66ccf8e7c28969d56863034d030134bf')
+md5sums_x86_64=('de9b7a90f0f5a13cfcaa3b01451d0337')
+## Alternative mirror, if your local one is throttled:
+#source_x86_64=("http://ftp.wsisiz.edu.pl/pub/pc/pozyteczne%20oprogramowanie/java/$pkgname-$pkgver-linux-x64.gz")
+
+package() {
+    cd ${pkgname}1.${_major}.0_${_minor}
+
+    msg2 "Creating directory structure..."
+    install -d "$pkgdir"/etc/.java/.systemPrefs
+    install -d "$pkgdir"/usr/lib/jvm/java-$_major-$pkgname/bin
+    install -d "$pkgdir"/usr/lib/mozilla/plugins
+    install -d "$pkgdir"/usr/share/licenses/java$_major-$pkgname
+
+    msg2 "Removing redundancies..."
+    rm    db/bin/*.bat
+    rm    db/3RDPARTY
+    rm    db/LICENSE
+    rm -r jre/lib/desktop/icons/HighContrast/
+    rm -r jre/lib/desktop/icons/HighContrastInverse/
+    rm -r jre/lib/desktop/icons/LowContrast/
+    rm    jre/lib/fontconfig.*.bfc
+    rm    jre/lib/fontconfig.*.properties.src
+    rm -r jre/plugin/
+    rm    jre/*.txt
+    rm    jre/COPYRIGHT
+    rm    jre/LICENSE
+    rm    jre/README
+    rm    man/ja
+
+    msg2 "Moving contents..."
+    mv * "$pkgdir"/$_jvmdir
+
+    # Cd to the new playground
+    cd "$pkgdir"/$_jvmdir
+
+    msg2 "Fixing directory structure..."
+    # Replace duplicate binaries in bin/ with links to jre/bin/
+    for i in $(ls jre/bin/); do
+        ln -sf "$_jvmdir/jre/bin/$i" "bin/$i"
+    done
+
+    # Suffix .desktops + icons (sun-java.png -> sun-java-$_jname.png)
+    for i in $(find jre/lib/desktop/ -type f); do
+        rename -- "." "-$_jname." $i
+    done
+
+    # Fix .desktop paths
+    sed -e "s|Exec=|Exec=$_jvmdir/jre/bin/|" \
+        -e "s|.png|-$_jname.png|" \
+    -i jre/lib/desktop/applications/*
+
+    # Move .desktops + icons to /usr/share
+    mv jre/lib/desktop/* "$pkgdir"/usr/share/
+    install -m644 "$srcdir"/*.desktop "$pkgdir"/usr/share/applications/
+
+    # Move confs to /etc and link back to /usr: /usr/lib/jvm/java-$_jname/jre/lib -> /etc
+    for new_etc_path in ${backup[@]}; do
+        # Old location
+        old_usr_path="jre/lib/${new_etc_path#*$_jname/}"
+
+        # Move
+        install -Dm644 "$old_usr_path" "$pkgdir/$new_etc_path"
+        ln -sf "/$new_etc_path" "$old_usr_path"
+    done
+
+    # Link NPAPI plugin
+    case "$CARCH" in
+        i686)   ln -sf $_jvmdir/jre/lib/i386/libnpjp2.so  "$pkgdir"/usr/lib/mozilla/plugins/libnpjp2-$_jname.so ;;
+        x86_64) ln -sf $_jvmdir/jre/lib/amd64/libnpjp2.so "$pkgdir"/usr/lib/mozilla/plugins/libnpjp2-$_jname.so ;;
+    esac
+
+    # Replace JKS keystore with 'ca-certificates-java'
+    ln -sf /etc/ssl/certs/java/cacerts jre/lib/security/cacerts
+
+    # Suffix man pages
+    for i in $(find man/ -type f); do
+        mv "$i" "${i/.1}-$_jname.1"
+    done
+
+    # Move man pages
+    mv man/ja_JP.UTF-8/ man/ja
+    mv man/ "$pkgdir"/usr/share
+
+    # Move/link licenses
+    mv db/NOTICE COPYRIGHT LICENSE *.txt "$pkgdir"/usr/share/licenses/java$_major-$pkgname/
+    ln -sf /usr/share/licenses/java$_major-$pkgname/ "$pkgdir"/usr/share/licenses/$pkgname
+
+    msg2 "Installing Java Cryptography Extension (JCE) Unlimited Strength Jurisdiction Policy Files..."
+    # Replace default "strong", but limited, cryptography to get an "unlimited strength" one for
+    # things like 256-bit AES. Enabled by default in OpenJDK:
+    # - http://suhothayan.blogspot.com/2012/05/how-to-install-java-cryptography.html
+    # - http://www.eyrie.org/~eagle/notes/debian/jce-policy.html
+    install -m644 "$srcdir"/UnlimitedJCEPolicyJDK$_major/*.jar jre/lib/security/
+    install -Dm644 "$srcdir"/UnlimitedJCEPolicyJDK$_major/README.txt \
+                   "$pkgdir"/usr/share/doc/$pkgname/README_-_Java_JCE_Unlimited_Strength.txt
+
+    msg2 "Enabling copy+paste in unsigned applets..."
+    # Copy/paste from system clipboard to unsigned Java applets has been disabled since 6u24:
+    # - https://blogs.oracle.com/kyle/entry/copy_and_paste_in_java
+    # - http://slightlyrandombrokenthoughts.blogspot.com/2011/03/oracle-java-applet-clipboard-injection.html
+    _line=$(awk '/permission/{a=NR}; END{print a}' "$pkgdir"/etc/java-$_jname/security/java.policy)
+    sed "$_line a\\\\n \
+        // (AUR) Allow unsigned applets to read system clipboard, see:\n \
+        // - https://blogs.oracle.com/kyle/entry/copy_and_paste_in_java\n \
+        // - http://slightlyrandombrokenthoughts.blogspot.com/2011/03/oracle-java-applet-clipboard-injection.html\n \
+        permission java.awt.AWTPermission \"accessClipboard\";" \
+    -i "$pkgdir"/etc/java-$_jname/security/java.policy
+}
diff --git a/src/lostfiles/PKGBUILD b/src/lostfiles/PKGBUILD
new file mode 100644
index 0000000..2b0fb39
--- /dev/null
+++ b/src/lostfiles/PKGBUILD
@@ -0,0 +1,16 @@
+# Contributor: graysky <graysky AT archlinux dot us>
+
+pkgname=lostfiles
+pkgver=3.25
+pkgrel=1
+pkgdesc='Find orphaned files not owned by any Arch packages'
+arch=('any')
+license=('GPL2')
+url="https://github.com/graysky2/lostfiles"
+source=("https://github.com/graysky2/$pkgname/archive/v$pkgver.tar.gz")
+sha256sums=('1c6a8c8fb98bdda81331ad6df91eb210a7bb8cfc2aa990f55a1b7713917e98c4')
+
+package() {
+	cd "$pkgname-$pkgver"
+	install -Dm755 $pkgname "$pkgdir/usr/bin/$pkgname"
+}
diff --git a/src/pacaur/PKGBUILD b/src/pacaur/PKGBUILD
new file mode 100644
index 0000000..83a8087
--- /dev/null
+++ b/src/pacaur/PKGBUILD
@@ -0,0 +1,42 @@
+pkgname=pacaur
+pkgver=4.6.10
+pkgrel=1
+pkgdesc="An AUR helper that minimizes user interaction"
+arch=('any')
+url="https://github.com/rmarquis/pacaur"
+license=('ISC')
+depends=('cower' 'expac' 'sudo' 'git')
+makedepends=('perl')
+backup=('etc/xdg/pacaur/config')
+source=("https://github.com/rmarquis/$pkgname/archive/$pkgver.tar.gz")
+md5sums=('d708774040efc197534eff3886d70425')
+
+build() {
+    cd "$pkgname-$pkgver"
+    pod2man --utf8 --section=8 --center="Pacaur Manual" --name="PACAUR"\
+        --release="$pkgname $pkgver" ./README.pod > ./pacaur.8
+}
+
+package() {
+    cd "$pkgname-$pkgver"
+
+    mkdir -p $pkgdir/etc/xdg/pacaur
+    install -D -m644 ./config $pkgdir/etc/xdg/pacaur/config
+    mkdir -p $pkgdir/usr/bin
+    install -D -m755 ./$pkgname $pkgdir/usr/bin/$pkgname
+    mkdir -p $pkgdir/usr/share/bash-completion/completions
+    install -D -m644 ./bash.completion\
+        $pkgdir/usr/share/bash-completion/completions/$pkgname
+    mkdir -p $pkgdir/usr/share/zsh/site-functions
+    install -D -m644 ./zsh.completion\
+        $pkgdir/usr/share/zsh/site-functions/_pacaur
+    mkdir -p $pkgdir/usr/share/man/man8
+    install -D -m644 ./pacaur.8 $pkgdir/usr/share/man/man8/pacaur.8
+    mkdir -p $pkgdir/usr/share/licenses/pacaur
+    install -D -m644 ./LICENSE $pkgdir/usr/share/licenses/pacaur/LICENSE
+    for i in {ca,da,de,es,fr,hu,it,ja,nl,pl,pt,ru,sk,sr,sr@latin,tr}; do
+        mkdir -p $pkgdir/usr/share/locale/$i/LC_MESSAGES/
+        msgfmt ./po/$i.po -o $pkgdir/usr/share/locale/$i/LC_MESSAGES/pacaur.mo
+    done
+}
+
diff --git a/src/pacman-contrib/PKGBUILD b/src/pacman-contrib/PKGBUILD
new file mode 100644
index 0000000..a27b5f3
--- /dev/null
+++ b/src/pacman-contrib/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: Daniel M. Capella <polyzen@archlinux.info>
+# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
+
+pkgname=pacman-contrib
+pkgver=0.0.1.r13.ge3536de
+pkgrel=1
+pkgdesc='pacman contributions (Git version)'
+url=https://git.archlinux.org/pacman-contrib.git
+arch=('i686' 'x86_64')
+arch=('any')
+license=('GPL')
+depends=('pacman') # Change to 'pacman' after release 5.0.2
+makedepends=('asciidoc' 'git')
+source=("git+$url")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  git describe --long --tags | sed -r 's/^v//; s/([^-]*-g)/r\1/; s/-/./g'
+}
+
+build() {
+  cd ${pkgname}
+  ./autogen.sh
+  ./configure --prefix=/usr --sysconfdir=/etc \
+    --localstatedir=/var --enable-git-version \
+    --with-vim-dir=/usr/share/vim/vimfiles
+  make V=1
+}
+
+check() {
+  make -C ${pkgname} check
+}
+
+package() {
+  cd ${pkgname}
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/src/pacman/PKGBUILD b/src/pacman/PKGBUILD
new file mode 100644
index 0000000..e35be5f
--- /dev/null
+++ b/src/pacman/PKGBUILD
@@ -0,0 +1,74 @@
+# Maintainer: Dave Reisner <d@falconindy.com>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: godane <slaxemulator@gmail.com.com>
+# Contributor: Andres Perera <aepd87@gmail.com>
+
+pkgname=pacman
+pkgver=5.0.1.96.gabb0578
+pkgrel=2
+pkgdesc="A library-based package manager with dependency support. git version."
+arch=('i686' 'x86_64')
+url="http://www.archlinux.org/pacman/"
+license=('GPL')
+depends=('bash' 'curl' 'gpgme' 'libarchive' 'pacman-mirrorlist')
+makedepends=('git' 'asciidoc')
+optdepends=('fakeroot: for makepkg usage as normal user')
+checkdepends=('python2' 'fakechroot')
+provides=("pacman=$pkgver" 'libalpm.so')
+options=('!libtool' '!strip')
+backup=(etc/pacman.conf
+        etc/makepkg.conf)
+#source=(git://git.archlinux.org/pacman.git)
+#source=("git+file:///home/mopar/projects/pacman")
+source=("git+https://github.com/moparisthebest/pacman")
+sha1sums=('SKIP')
+
+build() {
+  cd "pacman"
+
+  ./autogen.sh
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --enable-doc \
+    --enable-git-version \
+    --enable-debug \
+    --with-scriptlet-shell=/usr/bin/bash \
+    --with-ldconfig=/usr/bin/ldconfig
+
+  make
+}
+
+check() {
+  make -C "pacman" check
+}
+
+package() {
+  cd "pacman"
+
+  make DESTDIR="$pkgdir" install
+
+  # set things correctly in the default conf file
+  case $CARCH in
+    i686)
+      mychost="i686-pc-linux-gnu"
+      myflags="-march=i686 "
+      ;;
+    x86_64)
+      mychost="x86_64-unknown-linux-gnu"
+      myflags="-march=x86-64 "
+      ;;
+  esac
+
+  # install completion files
+  rm -r "$pkgdir/etc/bash_completion.d"
+  install -Dm644 scripts/completion/bash_completion "$pkgdir/usr/share/bash-completion/completions/pacman"
+  for f in makepkg pacman-key; do
+    ln -s pacman "$pkgdir/usr/share/bash-completion/completions/$f"
+  done
+
+  install -Dm644 scripts/completion/zsh_completion $pkgdir/usr/share/zsh/site-functions/_pacman
+}
+
+# vim: set ts=2 sw=2 et:
diff --git a/src/perl-convert-tnef/PKGBUILD b/src/perl-convert-tnef/PKGBUILD
new file mode 100644
index 0000000..de81d21
--- /dev/null
+++ b/src/perl-convert-tnef/PKGBUILD
@@ -0,0 +1,49 @@
+# Contributor: John D Jones III AKA jnbek <jnbek1972 -_AT_- g m a i l -_Dot_- com>
+# Generator  : CPANPLUS::Dist::Arch 1.32
+
+pkgname='perl-convert-tnef'
+pkgver='0.18'
+pkgrel='3'
+pkgdesc="Perl module to read TNEF files"
+arch=('any')
+license=('PerlArtistic' 'GPL')
+options=('!emptydirs')
+depends=('perl-io-stringy' 'perl-mime-tools')
+makedepends=()
+url='https://metacpan.org/release/Convert-TNEF'
+source=('http://search.cpan.org/CPAN/authors/id/D/DO/DOUGW/Convert-TNEF-0.18.tar.gz')
+md5sums=('6f69ff242a807b861c6e68a3d93a58f7')
+sha512sums=('00cbe54169c535e6d6d3b53a06eb47808a129d6397c73b5f2b53b93efba20f81d078c16edb7b0108bc037e2cb7f1c92719633519ea17088442ea8f63864eaf07')
+_distdir="Convert-TNEF-0.18"
+
+build() {
+  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
+      PERL_AUTOINSTALL=--skipdeps                            \
+      PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'"     \
+      PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
+      MODULEBUILDRC=/dev/null
+
+    cd "$srcdir/$_distdir"
+    /usr/bin/perl Makefile.PL
+    make
+  )
+}
+
+check() {
+  cd "$srcdir/$_distdir"
+  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
+    make test
+  )
+}
+
+package() {
+  cd "$srcdir/$_distdir"
+  make install
+  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
+}
+
+# Local Variables:
+# mode: shell-script
+# sh-basic-offset: 2
+# End:
+# vim:set ts=2 sw=2 et:
diff --git a/src/perl-convert-uulib/PKGBUILD b/src/perl-convert-uulib/PKGBUILD
new file mode 100644
index 0000000..46910a1
--- /dev/null
+++ b/src/perl-convert-uulib/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Yardena Cohen <yardenack at gmail dot com>
+# Contributor: Techlive Zheng <techlivezheng [at] gmail [dot] com>
+# Contributor: Filip S. Adamsen <fsa [at] fsadev [dot] com>
+# Contributor: David Zaragoza <david@zaragoza.com.ve>
+# Contributor: Piotr Beling <qwak@w8.pl>
+# Contributor: Wael Nasreddine <wael@phoenixlinux.org>
+# Contributor: Guillermo A. Amaral <me@guillermoamaral.com> (thewonka)
+# Contributor: Chih-mao Chen <pkmx.tw@gmail.com>
+
+pkgname='perl-convert-uulib'
+pkgver='1.5'
+pkgrel='1'
+pkgdesc='Perl interface to the uulib library (a.k.a. uudeview/uuenview).'
+_dist=Convert-UUlib
+arch=('any')
+url='http://search.cpan.org/~mlehmann/Convert-UUlib/'
+license=('GPL' 'PerlArtistic')
+depends=(perl perl-canary-stability)
+options=(!emptydirs)
+source=("http://search.cpan.org/CPAN/authors/id/M/ML/MLEHMANN/Convert-UUlib-${pkgver}.tar.gz")
+sha512sums=('92c8b6f3a72546dca21018ddf2863113904f550e3ed950a1898ed4abfcc48738e9ca374f5adbc3226df2db6beeb0e12879ae52cdd067a030c199766d53603ec1')
+
+build() {
+  cd "${srcdir}"/"${_dist}"-"${pkgver}"
+
+  unset PERL5LIB PERL_MM_OPT CPPFLAGS
+  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+
+  perl Makefile.PL
+  make
+}
+
+check() {
+  cd "${srcdir}"/"${_dist}"-"${pkgver}"
+
+  unset PERL5LIB PERL_MM_OPT
+  export PERL_MM_USE_DEFAULT=1
+
+  make test
+}
+
+package() {
+  cd "${srcdir}"/"${_dist}"-"${pkgver}"
+
+  unset PERL5LIB PERL_MM_OPT
+
+  make install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
+
+  find "${pkgdir}" -name '.packlist' -o -name 'perllocal.pod' -delete
+}
diff --git a/src/pkgsync/PKGBUILD b/src/pkgsync/PKGBUILD
new file mode 100644
index 0000000..d6976a3
--- /dev/null
+++ b/src/pkgsync/PKGBUILD
@@ -0,0 +1,22 @@
+# Contributor: moparisthebest <admin dot archlinux AT moparisthebest dot com>
+
+pkgname=pkgsync
+pkgver=1.01
+pkgrel=1
+pkgdesc='Sync installed packages across Arch installs'
+arch=('any')
+license=('GPL3')
+url="https://github.com/moparisthebest/$pkgname"
+backup=("etc/$pkgname/pkg_blacklist.list" "etc/$pkgname/pkg_exclude.list" "etc/default/$pkgname")
+source=("https://codeload.github.com/moparisthebest/$pkgname/tar.gz/v$pkgver")
+sha256sums=('0d04af19ed5ffad2814b2845849a46ce2d606b4ef8e93e0dffb3b0f0ed8e760d')
+
+package() {
+	install -d "${pkgdir}"/etc/{default,$pkgname}/
+
+	cd "$pkgname-$pkgver"
+
+	install -Dm744 $pkgname "$pkgdir/usr/bin/$pkgname"
+	install -Dm744 config/*.list "${pkgdir}/etc/$pkgname/"
+	install -Dm744 "config/$pkgname" "${pkgdir}/etc/default/"
+}
diff --git a/src/prosody-hg-stable/PKGBUILD b/src/prosody-hg-stable/PKGBUILD
new file mode 100644
index 0000000..30d891d
--- /dev/null
+++ b/src/prosody-hg-stable/PKGBUILD
@@ -0,0 +1,90 @@
+# $Id: PKGBUILD 143420 2015-10-08 11:02:55Z spupykin $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Maintainer: Dwayne Bent <dbb@dbb.io>
+# Maintainer: Tilman Vatteroth <tilman.vatteroth@uni-dortmund.de>
+# Contributor: Paul-Sebastian Manole <brokenthorn@gmail.com>
+# Contributor: Timothée Ravier <tim@siosm.fr>
+# Contributor: Christoph Stahl <christoph.stahl@uni-dortmund.de>
+
+pkgname=prosody-hg-stable
+pkgrel=1
+pkgver=0.10.r7036+.779a9ef6b4fd+
+pkgver() {
+  cd "$srcdir/prosody-hg"
+  printf "0.10.r%s.%s" "$(hg identify -n)" "$(hg identify -i)"
+}
+pkgdesc="Lightweight and extensible Jabber/XMPP server written in Lua (stable build from 0.10-branch)"
+arch=('i686' 'x86_64' 'armv7h')
+url="https://prosody.im/"
+license=('MIT')
+depends=('lua51' 'lua51-socket' 'lua51-expat' 'lua51-filesystem' 'libidn'
+         'openssl')
+makedepends=('mercurial')
+conflicts=('prosody')
+provides=('prosody')
+optdepends=(
+'lua51-sec: TLS encryption support' 
+'lua51-bitop: websocket support'
+'lua51-event: libevent support'
+)
+install=prosody.install
+backup=('etc/prosody/prosody.cfg.lua')
+source=("prosody-hg::hg+https://hg.prosody.im/0.10"
+        'prosody.tmpfile.d'
+        'sysuser.conf'
+        'prosody.service')
+
+prepare() {
+  cd prosody-hg
+
+  # disable logging to output and activate syslog
+    sed -i s/"info = "/"-- info = "/g prosody.cfg.lua.dist
+    sed -i s/"error = "/"-- error = "/g prosody.cfg.lua.dist
+    sed -i s/"--\ \"\*syslog\"\;"/"\"*syslog\"\;"/g prosody.cfg.lua.dist
+
+
+  # add pidfile and daemonize
+  # daemonize is important for systemd!
+    mv prosody.cfg.lua.dist prosody.cfg.lua.old
+
+    echo --Important for systemd >> prosody.cfg.lua.dist
+    echo -- daemonize is important for systemd. if you set this to false the systemd startup will freeze. >> prosody.cfg.lua.dist
+    echo daemonize = true >> prosody.cfg.lua.dist
+    echo 'pidfile = "/run/prosody/prosody.pid"'>> prosody.cfg.lua.dist
+    echo "" >> prosody.cfg.lua.dist
+    cat prosody.cfg.lua.old >> prosody.cfg.lua.dist
+    rm prosody.cfg.lua.old
+}
+
+build() {
+  cd prosody-hg
+  ./configure --ostype=linux --prefix=/usr --sysconfdir=/etc/prosody \
+    --datadir=/var/lib/prosody --with-lua-include=/usr/include/lua5.1 \
+    --cflags="${CFLAGS} -fPIC -Wall -Wextra -D_GNU_SOURCE" \
+    --ldflags="${LDFLAGS} -shared" --no-example-certs \
+    --runwith=lua5.1
+  make
+}
+
+package() {
+  cd prosody-hg
+  make DESTDIR="${pkgdir}" install
+  make DESTDIR="${pkgdir}" install -C tools/migration
+
+  install -Dm 0644 $srcdir/prosody.tmpfile.d "${pkgdir}"/usr/lib/tmpfiles.d/prosody.conf
+  install -Dm 0644 $srcdir/prosody.service "${pkgdir}"/usr/lib/systemd/system/prosody.service
+  install -Dm644 $srcdir/sysuser.conf "$pkgdir"/usr/lib/sysusers.d/prosody.conf
+
+  for i in tools/*.lua; do
+    install -Dm 0644 ${i} "${pkgdir}"/usr/share/prosody/${i}
+  done
+
+  install -Dm 0644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
+  rm "${pkgdir}"/etc/prosody/certs/*
+}
+
+# vim: ft=sh syn=sh ts=2 sw=2
+md5sums=('SKIP'
+         'dc8405a6a235b83dc8a0dcdf7b71cbaa'
+         '385ca73d9f6046f3636266ce9bf38797'
+         'e74045f27cb60908d535969906781f75')
diff --git a/src/python2-yenc/PKGBUILD b/src/python2-yenc/PKGBUILD
new file mode 100644
index 0000000..0b861d0
--- /dev/null
+++ b/src/python2-yenc/PKGBUILD
@@ -0,0 +1,28 @@
+# Maintainer: Clément Démoulins <clement@archivel.fr>
+# Contributor: Lucky <aur.archlinux.org [at] lucky.take0ver [dot] net>
+# Contributor: Jonathan Curran <jonc@icicled.net>
+
+pkgname=python2-yenc
+pkgver=0.4.0
+pkgrel=3
+pkgdesc="yEnc encoding/decoding module for python2"
+url="http://www.golug.it/yenc.html"
+arch=('i686' 'x86_64')
+license=("GPL")
+depends=("python2")
+conflicts=("python-yenc")
+replaces=("python-yenc")
+
+#source=("http://www.golug.it/pub/yenc/${_pkgname}-${pkgver}.tar.gz")
+source=("http://bitbucket.org/dual75/yenc/get/${pkgver}.tar.bz2")
+md5sums=('60e1a535b0e0c865c2cc4e7ddf18d9a4')
+
+build() {
+  cd "${srcdir}/dual75-yenc-ee6b73a5b14f"
+  python2 setup.py build
+}
+
+package() {
+  cd "${srcdir}/dual75-yenc-ee6b73a5b14f"
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+}
diff --git a/src/redis-desktop-manager/PKGBUILD b/src/redis-desktop-manager/PKGBUILD
new file mode 100644
index 0000000..4dd3b5e
--- /dev/null
+++ b/src/redis-desktop-manager/PKGBUILD
@@ -0,0 +1,69 @@
+# Maintainer: Vyacheslav Konovalov <vyachkonovalov@gmail.com>
+
+pkgname=redis-desktop-manager
+_pkgver=0.9.0-alpha2
+pkgver=${_pkgver/-/_}
+pkgrel=1
+pkgdesc='Open source cross-platform Redis Desktop Manager based on Qt 5'
+arch=('x86_64')
+url="https://redisdesktop.com/"
+license=('GPLv3')
+depends=('qt5-base' 'qt5-charts' 'qt5-imageformats' 'qt5-tools' 'qt5-declarative' 'qt5-quickcontrols' 'qt5-graphicaleffects' 'qt5-svg' 'libssh2')
+makedepends=('git' 'gcc')
+conflicts=('redis-desktop-manager-bin')
+source=("rdm::git://github.com/uglide/RedisDesktopManager.git#tag=${_pkgver}"
+        'rdm.sh'
+        'rdm.desktop')
+sha256sums=('SKIP'
+            'f469d9a5adce723904efe0f1b1db5d79807410f90aafb117f18ae108d8b2d391'
+            '4fac85cec4a7abe7254ff3a6f0382d9a6f2b712372ecbd74474a2f8efe9c4e3c')
+
+prepare() {
+  cd rdm/
+  git submodule update --init --recursive
+  git submodule add https://chromium.googlesource.com/linux-syscall-support 3rdparty/linux-syscall-support
+
+  python2 build/utils/set_version.py "${_pkgver}" > src/version.h
+  python2 build/utils/set_version.py "${_pkgver}" > 3rdparty/crashreporter/src/version.h
+
+  _lssdir='3rdparty/gbreakpad/src/third_party/lss/'
+  mkdir -p ${_lssdir}
+  cp 3rdparty/linux-syscall-support/linux_syscall_support.h ${_lssdir}
+  cd 3rdparty/gbreakpad
+  touch README
+}
+
+build() {
+  rm -rf $srcdir/rdm/bin
+
+  cd $srcdir/rdm/3rdparty/crashreporter
+  qmake CONFIG+=release DESTDIR="$srcdir/rdm/bin/linux/release" QMAKE_LFLAGS_RPATH=""
+  make -j 2
+
+  cd $srcdir/rdm/3rdparty/gbreakpad
+  ./configure
+  make -j 2
+
+  cd $srcdir/rdm/src
+  qmake && make
+}
+
+package() {
+  _instdir="$srcdir/rdm/bin/linux/release"
+  _bindir="$pkgdir/usr/share/redis-desktop-manager/bin"
+
+  mkdir -p "${_bindir}"
+  mkdir "$pkgdir/usr/share/licenses"
+  mkdir "$pkgdir/usr/share/pixmaps"
+  mkdir "$pkgdir/usr/share/applications"
+
+  install -Dm644 "$srcdir/rdm/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm755 "${_instdir}/rdm" "${_bindir}/rdm"
+  install -Dm755 "${_instdir}/crashreporter" "${_bindir}/crashreporter"
+  install -Dm755 "$srcdir/rdm.sh" "${_bindir}/rdm.sh"
+  install -Dm644 "$srcdir/rdm/src/resources/rdm.png" "$pkgdir/usr/share/pixmaps/rdm.png"
+  install -Dm644 "$srcdir/rdm.desktop" "$pkgdir/usr/share/applications/rdm.desktop"
+
+  mkdir "$pkgdir/usr/bin"
+  ln -s '/usr/share/redis-desktop-manager/bin/rdm.sh' "$pkgdir/usr/bin/rdm"
+}
diff --git a/src/sabnzbd/PKGBUILD b/src/sabnzbd/PKGBUILD
new file mode 100644
index 0000000..9b09c60
--- /dev/null
+++ b/src/sabnzbd/PKGBUILD
@@ -0,0 +1,47 @@
+pkgname=sabnzbd
+_pkgname=SABnzbd
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="A web-interface based binary newsgrabber with NZB file support"
+url="http://www.sabnzbd.org"
+arch=("any")
+license=("GPL")
+depends=("curl" "par2cmdline"
+         "python2" "python2-cheetah" "python2-yenc"
+         "sqlite" "unrar" "unzip")
+optdepends=("xdg-utils: registration of .nzb files" "python2-feedparser: rss support" "python2-pyopenssl: ssl support" "par2cmdline-tbb: par2 multi-threading")
+install="${pkgname}.install"
+backup=("etc/conf.d/sabnzbd" "opt/${pkgname}/${pkgname}.ini")
+source=("https://github.com/${pkgname}/${pkgname}/releases/download/${pkgver}/${_pkgname}-${pkgver}-src.tar.gz"
+        "${pkgname}" "${pkgname}.desktop" "addnzb.sh" "nzb.png" "sabnzbd.png" "x-nzb.xml" "${pkgname}.service" "${pkgname}.confd")
+md5sums=('03cec705efb742ab9a1d8d6dedbcee2f'
+         '48d60a1c626503c7fef1bc5374390513'
+         '36e5f0f60f28f67102682f80e33c6d4b'
+         '69b9bcbcf67ff3e7a4cdd9f26e001341'
+         '46fa8020fcfaad1e06d370fa3b0ea09a'
+         'b834ca5dfb63a5d06041c3174172ec09'
+         '11fb2cd1451e3725b08bfc2bd045be54'
+         'da07971fa3790ea4824ed4ce611b38f3'
+         '8fc2607a7961fc643ef4f6640166322a')
+
+package() {
+  mkdir -p "${pkgdir}/opt/${pkgname}"
+  touch "${pkgdir}/opt/${pkgname}/${pkgname}.ini"
+  cp -r "${srcdir}/${_pkgname}-${pkgver}/"* "${pkgdir}/opt/${pkgname}"
+
+  # Fix for issues with Python 3
+  find "${pkgdir}/opt/${pkgname}" -type f -exec sed -i 's/python/python2/g' {} \;
+  find "${pkgdir}/opt/${pkgname}" -type d -exec chmod 755 {} \;
+  find "${pkgdir}/opt/${pkgname}" -type f -exec chmod 644 {} \;
+  chmod 755 "${pkgdir}/opt/${pkgname}/${_pkgname}.py"
+
+  install -Dm755 "${srcdir}/${pkgname}"       "${pkgdir}/usr/bin/${pkgname}"
+  install -Dm644 "${srcdir}/${pkgname}.confd" "${pkgdir}/etc/conf.d/${pkgname}"
+  install -Dm644 "${srcdir}/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
+  install -Dm755 "${srcdir}/${pkgname}.desktop" \
+    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  install -Dm755 "${srcdir}/addnzb.sh"    "${pkgdir}/opt/${pkgname}/addnzb.sh"
+  install -Dm644 "${srcdir}/nzb.png"    "${pkgdir}/opt/${pkgname}/nzb.png"
+  install -Dm644 "${srcdir}/sabnzbd.png"  "${pkgdir}/opt/${pkgname}/sabnzbd.png"
+  install -Dm770 "${srcdir}/x-nzb.xml"    "${pkgdir}/opt/${pkgname}/x-nzb.xml"
+}
diff --git a/src/scallion/PKGBUILD b/src/scallion/PKGBUILD
new file mode 100644
index 0000000..a83cca2
--- /dev/null
+++ b/src/scallion/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Dylan <dylan@hashflo.net>
+
+pkgname=scallion
+pkgver=2.0
+pkgrel=1
+pkgdesc="Creates vanity GPG keys and .onion addresses (for Tor's hidden services) using OpenCL."
+arch=('i686' 'x86_64')
+url="https://github.com/lachesis/scallion"
+license=('MIT')
+makedepends=('git' 'mono')
+depends=('mono')
+optdepends=(
+  'opencl-nvidia: OpenCL support for NVIDIA'
+  'opencl-mesa: OpenCL support for AMD/ATI Radeon mesa'
+)
+source=('scallion.sh')
+sha256sums=('1090325b7cd46c5b90ac0c9c841ca6ccf15141fd3c7b2f409ebecf0db1d39dff')
+
+_gitroot="git://github.com/lachesis/scallion.git"
+_gitname=scallion
+
+build() {
+  cd "$srcdir"
+  msg "Connecting to GIT server...."
+
+  if [[ -d "$_gitname" ]]; then
+    cd "$_gitname" && git pull origin
+    msg "The local files are updated."
+  else
+    git clone "$_gitroot" "$_gitname"
+  fi
+
+  msg "GIT checkout done or server timeout"
+  msg "Starting build..."
+
+  rm -rf "$srcdir/$_gitname-build"
+  git clone "$srcdir/$_gitname" "$srcdir/$_gitname-build"
+  cd "$srcdir/$_gitname-build"
+
+  xbuild scallion.sln
+}
+
+package() {
+  install -Dm755 scallion.sh "$pkgdir/usr/bin/$pkgname"
+  install -d "$pkgdir/usr/share"
+  cp -r "$srcdir/$_gitname-build/$pkgname/bin/Debug" "$pkgdir/usr/share/$pkgname"
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/src/searx/PKGBUILD b/src/searx/PKGBUILD
new file mode 100644
index 0000000..afb9539
--- /dev/null
+++ b/src/searx/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Jake <ja.ke@posteo.de>
+# Based on searx-git, thanks to: 
+# Jean Lucas <jean at 4ray dot co> and Reventlov <contact+aur at volcanis dot me>
+
+pkgname=searx
+pkgver=0.10.0
+pkgrel=3
+pkgdesc="A privacy-respecting, hackable metasearch engine"
+arch=('any')
+url="https://asciimoo.github.io/searx/"
+license=('AGPL')
+makedepends=('openssl')
+depends=('python2-flask'
+        'python2-flask-babel'
+        'python2-requests'
+        'python2-lxml'
+        'python2-yaml'
+        'python2-dateutil'
+        'python2-pygments'
+        'python2-certifi'
+        'python2-pyasn1-modules'
+        'python2-ndg-httpsclient'
+        'python2-pysocks')
+conflicts=('searx-git')
+backup=('etc/searx/settings.yml')
+install=searx.install
+source=('https://github.com/asciimoo/searx/archive/v0.10.0.zip'
+        'searx.install'
+        'searx.service')
+sha512sums=('2290dde2e26b8b219e8613c2c79b17a6d0ecd9170cf02b7c6cfe6bc1c0a67ca09b60c18d194e7086701218483ae0941e8e2001fd99eedc36b17a6fead7b4f4a3'
+            'daf98a69d87dc78ea645a02146d67b0a2903b3b219edadf2e3c987c20d0751ac147b72fe185c74bfe3e0b154ed8ee4b9b503e7ca922548fad52157aada05803c'
+            '354ec9c88018108ce0a652647faefaa23afb7afe53b42259a43adf9395b854d02c2b6d350b8d17cf105a9283f62aee0788f7dc96c2676f67c77941d3ef6edc0c')
+
+
+package() {
+  cd $srcdir/searx-$pkgver
+
+  # Allow newer versions of the dependencies
+  sed -i "s|==|>=|g" requirements.txt
+  
+  # Generate a random secret key
+  sed -i -e "s/ultrasecretkey\" # change this!/`openssl rand -hex 32`\"/g" searx/settings.yml
+
+  python2 setup.py install --root=$pkgdir --optimize=1
+  
+  mv $pkgdir/usr/lib/python2.7/site-packages/{README.rst,searx/}
+  mv $pkgdir/usr/lib/python2.7/site-packages/{tests,searx/}
+  
+  mkdir -p $pkgdir/etc/searx
+  mv $pkgdir/usr/lib/python2.7/site-packages/searx/settings.yml $pkgdir/etc/searx/
+  ln -s /etc/searx/settings.yml $pkgdir/usr/lib/python2.7/site-packages/searx/settings.yml
+
+  install -Dm0644 ../searx.service $pkgdir/usr/lib/systemd/system/searx.service
+}
diff --git a/src/sonarr/PKGBUILD b/src/sonarr/PKGBUILD
new file mode 100644
index 0000000..7aa7661
--- /dev/null
+++ b/src/sonarr/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Daniel Egeberg <daniel.egeberg@gmail.com>
+# Contributor: Justin Dray <justin@dray.be>
+pkgname="sonarr"
+pkgver="2.0.0.4374"
+pkgrel=1
+pkgdesc="PVR for newsgroup users. Formerly known as NZBDrone"
+arch=(any)
+url="https://sonarr.tv"
+license=('GPL3')
+depends=('mono' 'libmediainfo' 'sqlite')
+optdepends=('sabnzbd: an NZB downloader'
+            'nzbget: an NZB downloader'
+            'transmission-cli: a torrent downloader (CLI and daemon version)'
+            'transmission-gtk: a torrent downloader (GTK+ version)'
+            'transmission-qt: a torrent downloader (Qt version)'
+            'deluge: a torrent downloader')
+install='sonarr.install'
+provides=('nzbdrone' 'nzbdrone-torrents')
+conflicts=('nzbdrone' 'nzbdrone-torrents')
+replaces=('nzbdrone' 'nzbdrone-torrents')
+source=("https://update.sonarr.tv/v2/master/mono/NzbDrone.master.${pkgver}.mono.tar.gz"
+        "sonarr.sh"
+        "sonarr.service")
+noextract=()
+sha512sums=('e18ec5af06f9a0c4fdd3caddcc303367bf963a4669653eec73cad96957b1bd61b35e106d2770da025796ee5c7e25790ead3e9b5b41070ac3dbc632ece2022e8c'
+            '84efa2eebd9afe6b74203aefdc3fdbd4088ecfad17dbe929396f1ffc639743b615a9b75566a0b45d6b7925bd5675368015047c6d65c1421ffe8712728f350695'
+            '438de225c38c26aaa15cae243b18d0be85f3f0e54f1297bf182082a0bdbd936d21928cdcdb899f0f18c6ec32ee88c2e0f0d29b8a2a1cdf98a8e1907cd6f36a2c')
+
+package() {
+    cd "$srcdir"
+
+    install -d -m 755 "${pkgdir}/var/lib/sonarr"
+
+    msg2 "Install Sonarr in /usr/lib"
+    install -d -m 755 "${pkgdir}/usr/lib/sonarr"
+    cp -dpr --no-preserve=ownership "${srcdir}/NzbDrone/"* "${pkgdir}/usr/lib/sonarr"
+
+    msg2 "Install executable into /usr/bin"
+    install -D -m755 "${srcdir}/sonarr.sh" "${pkgdir}/usr/bin/sonarr"
+
+    msg2 "Install sonarr.service"
+    install -D -m 644 "${srcdir}/sonarr.service" "${pkgdir}/usr/lib/systemd/system/sonarr.service"
+}
diff --git a/src/subsonic/PKGBUILD b/src/subsonic/PKGBUILD
new file mode 100644
index 0000000..f62f89c
--- /dev/null
+++ b/src/subsonic/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: M0Rf30
+# Contributors: Thom Wiggers <thom@thomwiggers.nl>
+# Contributors: hoban
+# Contributors: Nrm
+# Contributors: MattScherbatsky
+# Contributors: robozman
+
+pkgname=subsonic
+pkgver=6.0
+pkgrel=2
+pkgdesc="A free, web-based media streamer and jukebox."
+arch=('any')
+url="http://subsonic.org/"
+license=('CUSTOM')
+depends=('java-runtime-headless')
+conflicts=('subsonic')
+source=(http://subsonic.org/download/subsonic-${pkgver}-standalone.tar.gz      
+        'subsonic.service')
+backup=('var/lib/subsonic/db' 'var/lib/subsonic/subsonic.properties' 'var/lib/subsonic/subsonic.sh')
+install=$pkgname.install
+ 
+package() {
+  cd ${srcdir}
+  mkdir -p $pkgdir/var/lib/subsonic
+  mkdir -p $pkgdir/var/playlists
+  mkdir -p $pkgdir/usr/lib/systemd/system
+  mkdir -p $pkgdir/etc/
+  sed -i 's/SUBSONIC_HOME=\/var\/subsonic/SUBSONIC_HOME=\/var\/lib\/subsonic/' subsonic.sh
+  cp  * $pkgdir/var/lib/subsonic
+  rm $pkgdir/var/lib/subsonic/{subsonic.bat,subsonic-${pkgver}-standalone.tar.gz}
+  ln -fs /var/lib/subsonic/subsonic.sh $pkgdir/etc/subsonic.conf
+  cp $srcdir/subsonic.service $pkgdir/usr/lib/systemd/system
+  chmod +x $pkgdir/var/lib/subsonic/subsonic.sh
+}
+ 
+md5sums=('5bfb0c06585d087801a6b67c6cb2bd78'
+         '7cbbb9c8357992385c929e9f05be00be')
diff --git a/src/ttf-ms-fonts/PKGBUILD b/src/ttf-ms-fonts/PKGBUILD
new file mode 100644
index 0000000..066bd8c
--- /dev/null
+++ b/src/ttf-ms-fonts/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: birdflesh <antkoul at gmail dot com>
+# Contributor: Army <uli.armbruster@gmail.com>
+# Contributor: Thayer Williams <thayer@archlinux.org>
+# Contributor: dale <dale@archlinux.org>
+
+pkgname=ttf-ms-fonts
+pkgver=2.0
+pkgrel=10
+pkgdesc="Core TTF Fonts from Microsoft"
+arch=('any')
+url="http://corefonts.sourceforge.net/"
+license=('custom:microsoft')
+depends=('fontconfig' 'xorg-fonts-encodings' 'xorg-font-utils')
+makedepends=('libarchive>=3.0.2')
+provides=('ttf-font')
+install=$pkgname.install
+_sfpath="http://downloads.sourceforge.net/corefonts"
+source=($_sfpath/andale32.exe $_sfpath/arial32.exe  $_sfpath/arialb32.exe
+        $_sfpath/comic32.exe  $_sfpath/courie32.exe $_sfpath/georgi32.exe
+        $_sfpath/impact32.exe $_sfpath/times32.exe  $_sfpath/trebuc32.exe
+        $_sfpath/verdan32.exe $_sfpath/webdin32.exe)
+md5sums=('cbdc2fdd7d2ed0832795e86a8b9ee19a'
+         '9637df0e91703179f0723ec095a36cb5'
+         'c9089ae0c3b3d0d8c4b0a95979bb9ff0'
+         '2b30de40bb5e803a0452c7715fc835d1'
+         '4e412c772294403ab62fb2d247d85c60'
+         '4d90016026e2da447593b41a8d8fa8bd'
+         '7907c7dd6684e9bade91cff82683d9d7'
+         'ed39c8ef91b9fb80f76f702568291bd5'
+         '0d7ea16cac6261f8513a061fbfcdb2b5'
+         '12d2a75f8156e10607be1eaa8e8ef120'
+         '230a1d13a365b22815f502eb24d9149b')
+
+package() { 
+  install -dm755 "$pkgdir/usr/share/fonts/TTF"
+
+  for font in *.{ttf,TTF}; do
+    install -m644 $font "$pkgdir/usr/share/fonts/TTF/$(echo $font|tr A-Z a-z)"
+  done
+
+  install -Dm644 Licen.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
diff --git a/src/ttf-oxygen/PKGBUILD b/src/ttf-oxygen/PKGBUILD
new file mode 100644
index 0000000..400bfdf
--- /dev/null
+++ b/src/ttf-oxygen/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Michael Straube <michael_straube@web.de>
+# Contributor: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Antonio Rojas <arojas@archlinux.org>
+
+pkgname=ttf-oxygen
+epoch=1
+pkgver=5.4.3
+pkgrel=2
+pkgdesc='A desktop/gui font family for integrated use with the KDE desktop'
+url='https://projects.kde.org/projects/kde/workspace/oxygen-fonts'
+arch=('i686' 'x86_64') # CMake files are arch-dependent
+license=('custom:OFL' 'GPL' 'custom:GPL+FE')
+depends=('fontconfig' 'xorg-fonts-encodings' 'xorg-font-utils')
+makedepends=('extra-cmake-modules' 'fontforge')
+provides=('ttf-font')
+options=('!emptydirs')
+install=${pkgname}.install
+source=("http://download.kde.org/stable/plasma/${pkgver}/oxygen-fonts-${pkgver}.tar.xz")
+md5sums=('8d8ab61a65642a18a40de9f3945ce584')
+
+prepare() {
+  mkdir build
+}
+
+build() {
+  cd build
+  cmake ../oxygen-fonts-${pkgver} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DLIB_INSTALL_DIR=lib \
+    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="${pkgdir}" install
+
+  # Fix install path
+  install -d "${pkgdir}"/usr/share/fonts/TTF
+  mv "${pkgdir}"/usr/share/fonts/truetype/oxygen/*.ttf \
+    "${pkgdir}"/usr/share/fonts/TTF/
+
+  install -d "${pkgdir}"/usr/share/licenses/${pkgname}
+  install -m644 "${srcdir}"/oxygen-fonts-${pkgver}/COPYING-{GPL+FE.txt,OFL} \
+    "${pkgdir}"/usr/share/licenses/${pkgname}
+}
diff --git a/src/wallabag/PKGBUILD b/src/wallabag/PKGBUILD
new file mode 100644
index 0000000..ce118c0
--- /dev/null
+++ b/src/wallabag/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Philipp Schmitt (philipp<at>schmitt<dot>co)
+
+pkgname=wallabag
+pkgver=2.1.2
+pkgrel=1
+pkgdesc='Self hostable application for saving web pages'
+arch=('any')
+url='http://www.wallabag.org/'
+license=('MIT')
+depends=(
+    'php>=5.3.3'
+    'php-gd'
+    'php-tidy'
+    'pcre'
+)
+optdepends=(
+    'php-mysql: For MySQL storage'
+    'php-pgsql: For postgres storage'
+    'php-sqlite: For sqlite storage'
+    'rabbitmq: For async import'
+    'redis: For async import'
+)
+install="$pkgname.install"
+options=(!strip)
+source=("${pkgname}.tar.xz::http://wllbg.org/latest-v2-package")
+sha256sums=('f3acfde5a945bcd0a65f2549fc2f577bc6fc633ba901df27e7dc88c07feb2406')
+backup=("etc/webapps/${pkgname}/parameters.yml"
+        "usr/share/webapps/${pkgname}/parameters.yml"
+        "var/lib/${pkgname}/data/db/wallabag.sqlite"
+        "usr/share/webapps/${pkgname}/data/db/wallabag.sqlite")
+
+package() {
+    cd "${pkgdir}"
+    mkdir -p usr/share/webapps
+    mv "${srcdir}/release-${pkgver}" usr/share/webapps/${pkgname}
+
+    WALLABAG_CONF_DIR="${pkgdir}/usr/share/webapps/${pkgname}/app/config"
+
+    install -d "${pkgdir}/etc/webapps/${pkgname}/"
+    mv "${WALLABAG_CONF_DIR}"/parameters.yml ${pkgdir}/etc/webapps/${pkgname}/
+    chown -R http:http ${pkgdir}/etc/webapps/${pkgname}
+    ln -s /etc/webapps/${pkgname}/parameters.yml "${WALLABAG_CONF_DIR}"/
+
+    _VAR_DIR="${pkgdir}/var/lib/${pkgname}/"
+    install -d "$_VAR_DIR"
+    mv "${pkgdir}/usr/share/webapps/${pkgname}/"{data,var} "$_VAR_DIR"
+    ln -s "/var/lib/${pkgname}/"{data,var} "${pkgdir}/usr/share/webapps/${pkgname}/"
+    chown -R http:http "$_VAR_DIR"
+
+    chown -R http:http "${pkgdir}/usr/share/webapps/${pkgname}"
+}