emulationstation

This commit is contained in:
Travis Burtrum 2019-11-12 23:51:30 -05:00
parent 37aa7edf88
commit cdf49457c7
4 changed files with 82 additions and 0 deletions

View File

@ -0,0 +1,46 @@
# Maintainer: Guillaume Hayot <ghayot@postblue.info>
pkgname=emulationstation
_gitname=EmulationStation
pkgver=2.7.6
pkgrel=1
pkgdesc="Emulation Station is a flexible emulator front-end supporting keyboardless navigation and custom system themes."
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="https://github.com/RetroPie/EmulationStation"
license=('MIT')
install=emulationstation.install
depends=('vlc' 'alsa-lib' 'sdl2' 'boost-libs' 'freeimage' 'curl' 'libraw')
makedepends=('cmake' 'boost' 'freetype2' 'eigen' 'curl' 'git')
optdepends=('ttf-droid: Fallback fonts for Chinese/Japanese/Korean characters'
'dolphin-emu: GameCube and Wii support'
'mupen64plus: Nintendo 64 support'
'mednafen: NES and GBA support'
'zsnes: SNES support'
'stella: Atari 2600 support'
'ppsspp-headless: PSP support'
'steam: Steam support')
conflicts=(emulationstation-git)
source=("https://github.com/RetroPie/$_gitname/archive/v$pkgver.tar.gz"
"emulationstation.desktop"
"emulationstation.png")
sha256sums=('f56b4301ddd97beb990aed387d34e021ea1df6a2f1256cf361cf2bcefd1b6247'
'5564803e0a82e132ab507b9cd341b32d1ce5b8be527996fbe13607d90f1dde2c'
'ac589d9da5c258226f8de76e99afe2b07ac86030ced90d284d31b51193057f9c')
prepare() {
cd "$_gitname-$pkgver"
rm -rf external/pugixml
git clone https://github.com/zeux/pugixml.git external/pugixml
}
build() {
cd "$_gitname-$pkgver"
cmake .
make
}
package() {
install -Dm755 "$srcdir/$_gitname-$pkgver/emulationstation" "$pkgdir/usr/bin/emulationstation"
install -Dm644 "$srcdir/$_gitname-$pkgver/LICENSE.md" "$pkgdir/usr/share/licenses/emulationstation/LICENSE"
install -Dm644 "$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
install -Dm644 "$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
}

View File

@ -0,0 +1,25 @@
[Desktop Entry]
Name=EmulationStation
GenericName=EmulationStation
Comment=Front-end for emulators
Exec=emulationstation
Icon=emulationstation.svg
Terminal=false
Type=Application
StartupNotify=false
Categories=Game;Emulator;
[Desktop Action Windowed]
Name=Open as window
Exec=emulationstation --windowed
OnlyShowIn=Unity;GNOME;
[Desktop Action NoExit]
Name=Don't display exit button
Exec=emulationstation --no-exit
OnlyShowIn=Unity;GNOME;
[Desktop Action Vsync off]
Name=Open in standalone mode
Exec=emulationstation -vsync 0
OnlyShowIn=Unity;GNOME;

View File

@ -0,0 +1,11 @@
post_install() {
echo "An example systems configuration file will be created at ~/.emulationstation/es_systems.cfg on first run."
echo "See https://github.com/RetroPie/EmulationStation/blob/master/SYSTEMS.md on how to tell EmulationStation"
echo "what systems you have, what platform they correspond to (for scraping), and where the games are located."
echo ""
echo "See https://github.com/RetroPie/EmulationStation#writing-an-es_systemscfg for a configuration file example."
echo ""
echo "Default theme is quite ugly, you can clone one like https://github.com/RetroPie/es-theme-carbon"
echo "in ~/.emulationstation/themes/{theme name} and select it in the settings."
echo "See https://github.com/RetroPie/EmulationStation/blob/master/THEMES.md for documentation."
}

Binary file not shown.

After

Width:  |  Height:  |  Size: 4.8 KiB