moparisthebest/arch-ppa
1
0
Fork 0
mirror of https://github.com/moparisthebest/arch-ppa synced 2024-11-21 08:15:01 -05:00
Code Issues Releases Wiki Activity

sendxmpp-rs packages added

Browse Source
This commit is contained in:
Travis Burtrum 2019-02-09 15:06:03 -05:00
parent 27a8fb941c
commit aa0de23d7b
2 changed files with 78 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

40
src/sendxmpp-rs-git/PKGBUILD Normal file
View File

@ -0,0 +1,40 @@
# Maintainer: moparisthebest <admin dot archlinux AT moparisthebest dot com>
pkgname=sendxmpp-rs-git
pkgver=1.0.0.r0.g12ea8c5
pkgrel=1
pkgdesc="sendxmpp is the XMPP equivalent of sendmail. It is an alternative to the old sendxmpp written in Perl."
url="https://code.moparisthebest.com/moparisthebest/sendxmpp-rs"
makedepends=('cargo' 'git')
provides=('sendxmpp' 'sendxmpp-py')
conflicts=('sendxmpp' 'sendxmpp-py')
arch=('i686' 'x86_64' 'armv7h' 'armv6h')
license=('GPL')
backup=('etc/sendxmpp/sendxmpp.toml')
source=("$pkgname::git+https://code.moparisthebest.com/moparisthebest/sendxmpp-rs.git")
validpgpkeys=('81F1C22DD41109D4A9C0A7B5B070F8D97D1A0BBA') # moparisthebest <admin AT moparisthebest.com>
sha256sums=(SKIP)
conflicts=(sendxmpp-rs)
provides=(sendxmpp-rs=$pkgver)
pkgver() {
cd "$pkgname"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$pkgname"
cargo fetch
}
build() {
cd "$pkgname"
cargo build --release
}
package() {
cd "$pkgname"
install -Dm755 target/release/sendxmpp "$pkgdir/usr/bin/sendxmpp"
install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
install -Dm644 sendxmpp.toml "${pkgdir}/etc/sendxmpp/sendxmpp.toml"
}

38
src/sendxmpp-rs/PKGBUILD Normal file
View File

@ -0,0 +1,38 @@
# Maintainer: moparisthebest <admin dot archlinux AT moparisthebest dot com>
_pkgname=sendxmpp
pkgname=sendxmpp-rs
pkgver=1.0.0
pkgrel=1
pkgdesc="sendxmpp is the XMPP equivalent of sendmail. It is an alternative to the old sendxmpp written in Perl."
url="https://code.moparisthebest.com/moparisthebest/sendxmpp-rs"
makedepends=('cargo')
provides=('sendxmpp' 'sendxmpp-py')
conflicts=('sendxmpp' 'sendxmpp-py')
arch=('i686' 'x86_64' 'armv7h' 'armv6h')
license=('GPL')
backup=('etc/sendxmpp/sendxmpp.toml')
source=("$_pkgname-$pkgver.tar.gz::https://crates.io/api/v1/crates/$_pkgname/$pkgver/download"
"$_pkgname-$pkgver.tar.gz.asc::https://code.moparisthebest.com/attachments/f627adef-0e6b-48af-b57a-01d353b15e58"
)
validpgpkeys=('81F1C22DD41109D4A9C0A7B5B070F8D97D1A0BBA') # moparisthebest <admin AT moparisthebest.com>
sha256sums=('08cdf3bd4279022c7606f8da6633bea50f968f2761a63268524dbabe9a566e16'
'a0488ab400730e1e21eddd328de90a3eefb4044eeb2c6773ae2c6607303881f7'
)
prepare() {
cd "$_pkgname-$pkgver"
cargo fetch
}
build() {
cd "$_pkgname-$pkgver"
cargo build --release
}
package() {
cd "$_pkgname-$pkgver"
install -Dm755 target/release/sendxmpp "$pkgdir/usr/bin/sendxmpp"
install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
install -Dm644 sendxmpp.toml "${pkgdir}/etc/sendxmpp/sendxmpp.toml"
}